使用 Mathematica 和 StackOverflow API 观察新的 Mathematica 问题

Question

除非Mr.Wizard 正在度假，否则很难击败这种似乎具有无所不在和无所不知的现象。我们如何使用 Mathematica 和 StackOverflow API 超越他？

Answer 1

这是 Sjoerd 解决方案的一种变体。

主要区别在于使用停靠单元格而不是弹出对话框。该单元格有一个指向新帖子的链接，以及一个按钮，可以将停靠的单元格清除到之前的状态。

另一个区别是使用问题 ID 而不是标题来确定新帖子。我知道标题有时会被编辑，所以在这种情况下会触发新帖子。

storedTitle = "";
storedID = 0;
mySOWatchTask = 
  CreateScheduledTask[{lastTitle, 
     lastID} = {"title", 
      "question_id"} /. ("questions" /. 
        Import["http://api.stackoverflow.com/1.1/questions?key=       \
         QEpjCjsXYE6s_kZEkFr4Lw&page=1&pagesize=1&sort=creation&\
tagged=                mathematica", "JSON"])[[1]];
   If[lastID != storedID,
    storedTitle = lastTitle;
    storedID = lastID;
    SetOptions[$FrontEndSession, 
     DockedCells -> 
      Cell[BoxData[
        ToBoxes[Style[
          With[{dock = Options[$FrontEndSession, DockedCells]}, 
           Grid[{{Button[Style["\[CircleTimes]", 16], 
               SetOptions[$FrontEndSession, dock], 
               Appearance -> None], "New StackOverflow question: ", 
              Hyperlink[lastTitle, 
               "http://stackoverflow.com/questions/" <> 
                ToString[lastID]]}}, 
            Alignment -> {{Left, Left, Left}}, 
            ItemSize -> {{2, 14, Scaled[0.7]}}]], 
          FontFamily -> "Times"]]], "DockedCell", 
       Background -> Orange]]; EmitSound[Sound[SoundNote[]]]];, 60];

Answer 2

其实很简单。您只需要以下内容。

定义一个监视任务：

storedTitle = "";

mySOWatchTask =
  CreateScheduledTask[
   {
    lastTitle = 
    "title" /. ("questions" /. 
        Import["http://api.stackoverflow.com/1.1/questions?key=\
                QEpjCjsXYE6s_kZEkFr4Lw&page=1&pagesize=1&sort=creation&tagged=\
                mathematica", "JSON"])[[1]];
    If[lastTitle != storedTitle, 
      storedTitle = lastTitle; 
      EmitSound[Sound[SoundNote[]]]; 
      MessageDialog["New question: " <> lastTitle]
    ];
    },
   60
   ];

然后开始：

StartScheduledTask[mySOWatchTask];

停止：

 StopScheduledTask[mySOWatchTask];

看看什么在运行：

 ScheduledTasks[] // Shallow

删除任务：

 RemoveScheduledTask[mySOWatchTask];

或所有任务：

RemoveScheduledTask[ScheduledTasks[]];

这会每分钟轮询一次 SO (the minimum that is not seen as abusive)，并在出现新的 Mathematica 问题时显示一个对话框并播放声音。

它的美妙之处在于：它使用 Mathematica 8，我们都知道 Mr.Wizard 还没有那个（还）;-)

请注意，SO API 被大量缓存，因此可能不会直接响应。我也没有对此进行广泛的测试。

编辑
请注意，上面使用的密钥 (app-id) 仅供这个小型 Mathematica 应用程序使用。如果您需要一个用于不同的应用程序，您可以自己通过一个快速而轻松的过程获得一个here。我花了不到一分钟的时间。