分组然后获取动态日期列中的数据总和答案

【问题标题】：Grouping then getting the sum of data in dynamic dated columns分组然后获取动态日期列中的数据总和
【发布时间】：2019-06-19 00:18:50
【问题描述】：

我目前正在为我的公司开发资源跟踪器，我每周都有每个人的容量数字（周在列中，每个人的信息在行中）。我需要能够对每个工作角色在特定月份的所有时间进行汇总，以便能够进行报告。

我目前考虑通过选择 4 周来对日期进行分组，但由于我的字段是动态的并且有大约 5 周的月份，因此无法准确地报告该月份的数字。

很遗憾，由于日期在列而不是行中，因此您无法透视信息。

我还没有找到任何可用于获取该信息的公式/代码。

在图片中，我添加了我希望能够动态求和的信息。红色勾勒出月份，绿色勾勒出工作角色信息。

因此，我希望能够汇总“7 月”下的所有信息，然后将其他月份的所有信息汇总起来，这样我就可以每月向我的利益相关者提供每个人/工作角色有多少天容量的数字那个月。

【问题讨论】：

我们开始吧：docs.google.com/spreadsheets/d/… 这将是容量选项卡。我很可能会在另一个选项卡中处理信息
工作表是私有的
我的公司已锁定床单，因此我无法分享。我已经添加了一张信息图片和更多关于我正在寻找的信息。

标签： filter google-sheets google-sheets-formula array-formulas google-sheets-query

【解决方案1】：

=ARRAYFORMULA(QUERY({INDIRECT("Sheet1!B3:B"&COUNTA(Sheet1!B3:B)+2), 
 MMULT(QUERY(TRANSPOSE(QUERY(TRANSPOSE(Sheet1!E2:Z), 
 "where month(Col1)+1=7 and year(Col1)=2019", 0)),
 "where Col1 is not null offset 1", 0), ROW(INDIRECT("A1:A"&COUNTA(
 FILTER(Sheet1!A2:2, MONTH(Sheet1!A2:2)=7, YEAR(Sheet1!A2:2)=2019))))^0)}, 
 "select Col1, sum(Col2) group by Col1 label sum(Col2)''", 0))

【讨论】：

谢谢，这基本上就是我需要的。但是，我需要在所有月份而不是特定一个月内执行此操作，然后使用该信息进行调整并形成图表。因此，根据您发送的内容，我将其更改为从员工姓名中扣除。我只是想知道是否有一个可以动态的解决方案，因此使用示例 MONTH(Sheet1!A2:2)=7 可以将“7”链接到一个单元格以及 "where month(Col1)+ 1=6。这样它是自我维持的，因为我想确保我的所有团队都可以使用它，而不仅仅是技术人员。我会继续玩，看看
试试：=ARRAYFORMULA(QUERY({INDIRECT("Sheet1!B3:B"&COUNTA(Sheet1!B3:B)+2), MMULT(QUERY(TRANSPOSE(QUERY(TRANSPOSE(Sheet1!E2:Z), "where month(Col1)+1="&A1&" and year(Col1)=2019", 0)), "where Col1 is not null offset 1", 0), ROW(INDIRECT("A1:A"&COUNTA( FILTER(Sheet1!A2:2, MONTH(Sheet1!A2:2)=A1, YEAR(Sheet1!A2:2)=2019))))^0)}, "select Col1, sum(Col2) group by Col1 label sum(Col2)''", 0))
QUERY 中的月份从零开始，这就是 +1 更正的原因。