潜艇之间的VBA传递值

Question

我正在尝试学习如何在 subs 之间来回传递值。我创建了几个宏子，它们最终在它们之间一遍又一遍地使用相同的代码行。首先，我希望能够查找/计算列数和行数。这是我到目前为止所拥有的，但它不起作用。

我还想将它从列扩展到行。

Public Sub main()
Dim lCols As Integer
Dim lRows As Integer

   lCols = countCols(Sheet1)

   Sheet1.Range("M2").Value = lCols

End Sub

Public Function countCols(sheetValue As Worksheet) As Variant
       countCols = sheetValue.Cells(Rows.Count, 1).End(x1Up).Row
   Exit Function
End Function

现在它挂在函数中......似乎它没有将“Sheet1”传递给 sheetValue。

Answer 1

几点：

1. 最好声明行变量和列变量一样长。见this。
2. 当您将变量lCols, lRows 声明为Integer 时，函数的返回类型也应该是Integer
3. 在您的情况下无需使用Exit Function。 Exit Function 用于退出函数并执行函数调用之后的语句。但是，在您的情况下，函数本身在那里结束，因此不需要退出。

尝试关注

Public Sub main()
    Dim lCols As Long, lRows As Long  'declared as long
    Dim ws As Worksheet

    Set ws = ThisWorkbook.Sheets("Sheet2")  'change Sheet2 to your data sheet

    lCols = countCols(ws)
    lRows = countRows(ws)

    ws.Range("M2").Value = lCols
    ws.Range("N2").Value = lRows

End Sub

Public Function countCols(sheetValue As Worksheet) As Long  'should return long
       countCols = sheetValue.Cells(1, sheetValue.Columns.Count).End(xlToLeft).Column
End Function

Public Function countRows(sheetValue As Worksheet) As Long  'should return long
       countRows = sheetValue.Cells(sheetValue.Rows.Count, 1).End(xlUp).Row
End Function