Fortran 95 中的二进制搜索

Question

我尝试在 Fortran 95 中使用递归函数实现二进制搜索。

我的错误信息是：/usr/bin/timeout: the monitoring command dumped core

有人知道我该如何解决这个问题吗？

这个小程序的返回值应该是2。

另外：如何扩展我的代码以返回数组“ar”的位置编号以知道我可以在哪里添加我的新元素（即“2.9”）？如果是 2.9，它应该返回 2。另一个例子，如果我使用 7.3 而不是 2.9，它应该返回 6（在数组“ar”的 7.0 和 8.0 之间）。

program h
   real, dimension(7) :: ar
   integer :: s
   real :: outp
   ar = (/2.0, 3.0, 4.0, 5.0, 7.0, 8.0, 9.0/)
   s = sizeof(ar)
   outp = findAr(ar, 1, s, 3.0)
   print*, outp
end program h

recursive function findAr(ar, l, r, x) result(a)
        real, dimension(size(ar)), intent(in)  :: ar
        integer, intent(in) :: l, r
        real, intent(in) :: x
        integer :: midd
        real :: a
        if (r >= 1) then
            midd = l + (r - 1) / 2
            if (ar(midd) == x) then
                a = midd
            else if (ar(midd) > x) then
                a = findAr(ar, l, midd - 1, x)
                else
                a = findAr(ar, midd + 1, r, x)
            end if
        end if
end function findAr

Answer 1

编译器错误可以按照 cmets 对您的问题的指定解决。

---

关于您的第二个问题：如何扩展您的代码以在数组元素之间搜索值。可以以相同的方式询问数组之外​​的值（例如，小于其最小值）。

以下代码未使用递归函数，也不是您的代码的扩展。 您应该记住，不必要的函数调用会产生一些开销，并可能导致性能损失。

module bin_search_m
  implicit none
contains
  function bin_search(x, x1) result(i)
    !! find index of nearest value in sorted array
    real,              intent(in) :: x(:)
      !! sorted array
    real,              intent(in) :: x1
      !! value to find
    integer                       :: i
      !! return array index

    integer :: i0, i1

    ! starting interval is the whole array
    i0 = 1
    i1 = size(x)

    ! test if x1 is outside of interval [x(1), x(end)]
    if (x1 <= x(i0)) then
      i = i0
      return
    end if
    if (x1 >= x(i1)) then
      i = i1
      return
    end if

    ! binary search
    do while (i1 > (i0 + 1))
      i = (i1 + i0) / 2
      if      (x(i) < x1) then
        i0 = i
      else if (x(i) > x1) then
        i1 = i
      else
        return
      end if
    end do

    ! pick index of value that is closer
    i = merge(i0, i1, ((2 * x1) < (x(i0) + x(i1))))
  end function
end module