使用 Fortran 的数组问题中的二进制搜索

Question

我正在使用 Schaum 的 Fortran 77 编程大纲，并且有一个关于使用括号组值方法进行二分搜索的示例。首先是代码：

    INTEGER X(100)
    INTEGER RANGE
    INTEGER START , FINISH

    PRINT *, 'Number of values ?'
    READ *, N
    DO 10 I = 1, N
        READ *, X(I)
    END DO 

    PRINT *, 'Enter Value'
    READ *, VAL

    START =  1 
    FINISH = N
    RANGE = FINISH - START 
    MID = (START + FINISH) /2

    DO WHILE( X(MID) .NE. VAL .AND. RANGE .NE. 0)
      IF (VAL .GT. X(MID))THEN
        START = MID 
      ELSE 
        FINISH = MID
      END IF
      RANGE = FINISH - START
      MID = (START + FINISH)/2
    END DO 

    IF( X(MID) .NE. VAL) THEN
      PRINT *, VAL, 'NOT FOUND'
    ELSE
      PRINT *, 'VALUE AT' , MID
    END IF
    END

问题是，当我输入 7 个值数组时

2 | 9 | 11 | 23 | 49 | 55 | 66

例如搜索66，当

MID = 5

，下一个循环的新 MID 变为 6 。但是当它是 6 时，它不能为下一个循环增加，因为

MID = (开始 + 完成)/2 = (6+7)/2 = 6

当然应该是 7。

它仍然在 6。当然，我的程序从来没有给我输出。 我该怎么办？

Answer 1

这只是一个错字，或者当他们从 C 版本翻译它并不得不更改索引时可能有人感到困惑。

循环中的关键不变量是，如果值在列表中，则该值必须落在数组中从索引开始到结束的某个位置，包括索引。但是一旦你排除了中间，它应该被从列表中取出。但它不在这里，所以列表总是太长，你会遇到你看到的问题。

正确的版本设置从 mid+1 开始，或从 mid-1 结束，以排除 mid。以 Fortran 90 风格编写的更正代码：

program binarysearch

    implicit none
    integer, allocatable, dimension(:) ::  x
    integer :: range, start, finish, mid
    integer :: i, n, val

    print *, 'Number of values ?'
    read *, N
    allocate( x(N) )

    do i = 1, n
        READ *, x(i)
    end do

    print *, 'Enter Value'
    read *, VAL

    start =  1
    finish = N
    range = finish - start
    mid = (start + finish) /2

    do while( x(mid) /= val .and. range >  0)
      if (val > x(mid)) then
        start = mid + 1
      else
        finish = mid - 1
      end if
      range = finish - start
      mid = (start + finish)/2
    end do

    if( x(mid) /= val) then
      print *, val, 'NOT FOUND'
    else
      print *, 'VALUE AT' , mid
    end if

    deallocate( x )

end program binarysearch