NetLogo：如何根据从另一个向量中随机选择的值构建一个新向量？

Question

我有一个 10 位数字的向量“原始”。现在我想创建基于“原始”的矢量“适应”。 'adapted' 应该在同一位置从 'original' 中取 n 个大于 0 的随机值，并用 0 填充其余的值，例如：

原始 = [2 3 6 2 0 5 7 2 4 8] 适应 = [2 0 0 0 0 5 0 2 0 0]

to go

  let n 3
  let vector-dimension 10

  let original []
  repeat vector-dimension
    [set original lput random 10 original]

   print original

   
   let adapted []

   while [sum (map [ [v1] -> ifelse-value (v1 > 0) [1] [0] ] (adapted)) != n]
     [set adapted (map [ [v1] -> ifelse-value ( (vector-dimension / n) * (100 / vector-dimension) > random-float 100) [v1] [0] ] (original)) ]
    
   print adapted
   
end

此代码有效，但速度很慢。我怎样才能更快地做到这一点？

Answer 1

怎么样：

to-report report-rand-n [ base n ]
  let indices ( range 0 (length base)) 
  let subset n-of n indices
  let out ( map [ [ i v ] -> ifelse-value ( member? i subset ) [v] [0] ] indices base)
  report out
end

此报告者创建一个索引列表（0 到传递的 base 的长度），然后随机选择 n 传递给 ifelse-value 的索引数量以返回基数中的原始值（如果 @ 987654325@ 是选定的indices) 或 0 之一。

测试：

to test
  let original [2 3 6 2 0 5 7 2 4 8]
  print report-rand-n original 3
  print report-rand-n original 3
  print report-rand-n original 5
  print report-rand-n original 5
end

observer> test
[2 0 6 0 0 0 0 0 4 0]
[2 0 0 0 0 0 0 2 0 8]
[2 0 0 0 0 5 0 2 4 8]
[0 0 6 2 0 5 0 0 0 8]

编辑：

to test
  let original [2 3 6 2 0 5 7 2 4 8]
  print word "testing: " original
  print report-rand-n original 3
  
  let few-digits [ 0 0 0 1 0 0 0 ]
  print word "testing: " few-digits
  print report-rand-n few-digits 3
  print ""

end

to-report report-rand-n [ base n ]
  ; create list of indices
  let indices ( range 0 (length base)) 
  
  ; To address point 1) in your comment:
  ; keep only indices that correspond to a value > 0 in base
  let indices-over-zero filter [ i -> item i base > 0 ] indices
  
  ; To address point 2 in your comment:
  ; If the length of indices over zero is less than n, replace n
  ; with the length of indices over zero
  if length indices-over-zero < n [
    set n length indices-over-zero
  ]
  let subset n-of n indices-over-zero
  let out ( map [ [ i v ] -> ifelse-value ( member? i subset ) [v] [0] ] indices base)
  report out
end