SAS 邻接矩阵创建

Question

我创建了这个表：

从这个我想创建一个邻接矩阵来显示有多少employee_id 的表共享。它看起来像这样（我认为）： 我不确定我是否以正确的方式解决这个问题。我想我可能做错了。我知道如果我有更多 SAS 产品，这可能会更容易，但我只有基本的 SAS 企业指南可以使用。

非常感谢您的帮助。谢谢你。

Answer 1

这是使用 PROC CORR 的另一种方式，它仍然比上述解决方案更好。而且您不需要过滤 - 变量无关紧要，您只需在 PROC CORR 过程中指定它们。

data id;
input id:$4. human alien wizard;
cards;
1005 1 1 0
1018 0 0 1
1022 0 0 1
1024 1 0 0
1034 0 1 0
1069 0 1 0
1078 1 0 0
1247 1 1 1
;;;;
run;

ods output sscp=want;
proc corr  data=id  sscp ;
    var human alien wizard;
run;

proc print data=want;
    format _numeric_ 8.;
run;

结果是：

                   Obs    Variable       human       alien      wizard

                   1      human             4           2           1
                   2      alien             2           4           1
                   3      wizard            1           1           3

Answer 2

我认为这是您想要的，但它并没有给出您显示的答案。

data id;
   input id:$4. human alien wizard;
   cards;
1005 1 1 0
1018 0 0 1
1022 0 0 1
1024 1 0 0
1034 0 1 0
1069 0 1 0
1078 1 0 0
1247 1 1 1
;;;;
   run;

proc corr noprint nocorr sscp out=sscp;
   var human alien wizard;
   run;
proc print;
   run;

Answer 3

我能够使用这个得到答案，尽管它不包括我想要的最后一个单元格（human_alien_wizard）：

proc transpose data=FULL_JOIN_ALL3 out=FULL_JOIN_ALL3_v2;
  by employee_id;
  var human_table alien_table wizard_table;
run; 

proc sql;
  create table FULL_JOIN_ALL3_v3 as
  select distinct a._name_ as anm,b._name_ as bnm,
  count(distinct case when a.col1=1 and b.col1=1 then a.employee_id else . end) as smalln
  from FULL_JOIN_ALL3_v2 a, FULL_JOIN_ALL3_v2 b
  where a.employee_id=b.employee_id
  group by anm,bnm
; 

proc tabulate data=FULL_JOIN_ALL3_v3;
 class anm bnm;
 var smalln;
 table anm='',bnm=''*smalln=''*sum=''*f=best3. / rts=5;
run;