递归与。尾递归

Question

我对函数式编程很陌生，尤其是下面使用的 Scheme。我正在尝试制作以下递归的尾递归函数。 基本上，该函数的作用是对两个字符串的对齐进行评分。当给定两个字符串作为输入时，它会比较每个“列”字符并根据在名为 scorer 的函数中实现的评分方案为该对齐累积分数，该函数由下面代码中的函数调用。

我有点想使用辅助函数来累积分数，但我不太确定如何做到这一点，因此我将如何使函数低于尾递归？

(define (alignment-score string_one string_two)
  (if (and (not (= (string-length string_one) 0))
           (not (=(string-length string_two) 0)))
      (+ (scorer (string-ref string_one 0)
                 (string-ref string_two 0))
         (alignment-score-not-tail
          (substring string_one 1 (string-length string_one))
          (substring string_two 1 (string-length string_two))
          )
       )
    0)
)

Answer 1

只是想制作一个使用字符列表的 Chris 答案的变体：

(define (alignment-score s1 s2)
  (let loop ((score 0)
             (l1 (string->list s1))
             (l2 (string->list s2)))
    (if (or (null? l1) (null? l2))
        score
        (loop (+ score (scorer (car l1)
                               (car l2)))
              (cdr l1)
              (cdr l2)))))

停在那里没用。由于这现在已成为列表迭代，我们可以使用更高阶的过程。通常我们想要fold-left 或foldl 和SRFI-1 fold 是不需要列表长度相同的实现：

; (import (scheme) (only (srfi :1) fold)) ; r7rs    
; (import (rnrs) (only (srfi :1) fold))   ; r6rs    
; (require srfi/1)                        ; racket

(define (alignment-score s1 s2)
  (fold (lambda (a b acc)
          (+ acc (scorer a b)))
        0
        (string->list s1)
        (string->list s2)))

如果您累积并且顺序无关紧要，请始终选择左折叠，因为它在 Scheme 中始终是尾递归的。

Answer 2

下面是累加器的样子：

(define (alignment-score s1 s2)
  (define min-length (min (string-length s1) (string-length s2)))
  (let loop ((score 0)
             (index 0))
    (if (= index min-length)
        score
        (loop (+ score (scorer (string-ref s1 index)
                               (string-ref s2 index)))
              (+ index 1)))))

在这种情况下，score 是累加器，它从 0 开始。我们还有一个 index（也从 0 开始）来跟踪要抓取的字符串中的哪个位置。基本情况是，当我们到达任一字符串的末尾时，返回到目前为止累积的 score。