您可能很想在各种报告事件处理程序中使用 VBA，但即使这可能有效，根据我的经验，这只会导致试图让所有内容正确格式化的问题。相反，我建议创建一个新的报表，每行都有一个页码。从排序后的页码列表中获取主报表，并通过页码字段绑定多列子报表。使用一个简单的 VBA 过程填充报表，该过程可以根据您的方案正确地对行进行分页。
首先是报表（根据需要添加约束）：
CREATE TABLE SubReportTable (PageNum LONG, PageOrdinal LONG, _
Ordinal LONG, LastPage BIT, [Date of Service] DATE, [Location] TEXT)
关于子报告：
- 设置 RecordSoucre 属性：
SubReportTable（或者指定按所需字段排序的查询）
- 将列数设置为 4 以及其他列设置（填充、方向等）。
- 在“详细信息”部分和其他适当的控件上将 CanGrow 属性设置为
No。
- 调整列和详细信息部分的大小以适合页面上的所有列。 （这可能需要在主窗体上的打印预览和设计之间来回切换。）
在主报表上，设置以下属性：
-
RecordSource 属性：
SELECT SubReportTable.PageNum FROM SubReportTable WHERE (((SubReportTable.LastPage)=False)) GROUP BY SubReportTable.PageNum ORDER BY SubReportTable.PageNum
- 详细部分属性强制新页面到
After Section。
- SubReport 对象的 Link Master Fields 和 Link Child Fields 都与
PageNum
- 调整 SubReport 对象的大小以适合所有列。
将主报告上的行为复制到单独的“最后一页”报告中。设置此报告以根据报告表中的分页数据选择适当的记录子集（即LastPage = True）。根据具有 16 条记录的最后一页的格式不同，它可能还需要为 16 条记录创建单独的子报表，但您可能会使用与主报表相同的子报表...这将是您的问题确定。
-
RecordSource 属性：
SELECT SubReportTable.PageNum FROM SubReportTable WHERE ((SubReportTable.LastPage = True)) GROUP BY SubReportTable.PageNum ORDER BY SubReportTable.PageNum
最后是一些用于填充报表的代码。您可以直接从 VBA 即时窗口运行此过程，也可以将其放在某个按钮的单击事件处理程序中。可以调整分页逻辑以在最后一页上获得适量的记录。
Public Sub PrepareSubReporTable()
On Error GoTo Catch_PrepareSubReporTable
Dim db As Database
Dim rs As Recordset2
Dim rows As Long, pgs24 As Long, rowsLast24 As Long, rows16 As Long
Dim i As Long, p As Long, pi As Long
Set db = CurrentDb
db.Execute "DELETE * FROM [SubReportTable]", dbFailOnError
db.Execute _
"INSERT INTO SubReportTable ( PageNum, PageOrdinal, Ordinal, LastPage, [Date of Service], [Location] )" & _
" SELECT Null AS PageNum, Null AS PageOrdinal, Null AS Ordinal, False as LastPage," & _
" [Data].[Date of Service], [Data].[Location]" & _
" FROM [Data]" & _
" ORDER BY [Data].[Date of Service], [Data].[Location];", _
dbFailOnError
rows = db.OpenRecordset("SELECT Count(*) FROM SubReportTable").Fields(0)
pgs24 = rows \ 24
rows16 = rows - 24 * pgs24
If rows16 > 16 Then
rowsLast24 = rows16
pgs24 = pgs24 + 1
rows16 = 0
Else
rowsLast24 = 24
End If
Set rs = db.OpenRecordset( _
"SELECT * FROM SubReportTable" & _
" ORDER BY [Date of Service], [Location];")
i = 0
Do Until rs.EOF
p = i \ 24 + 1
rs.Edit
rs![PageNum] = p
If p > pgs24 Then
rs![lastPage] = True
pi = (i - pgs24 * 24) Mod 16 + 1
Else
pi = i Mod 24 + 1
End If
rs![PageOrdinal] = pi
i = i + 1
rs![Ordinal] = i
rs.Update
rs.MoveNext
Loop
rs.Close
Exit Sub
Catch_PrepareSubReporTable:
MsgBox Err.Number & ": " & Err.Description, _
vbOKOnly Or vbExclamation, "Error in PrepareSubReporTable"
End Sub
现在生成主报告和最后一页报告，可以手动生成，也可以使用 VBA 代码生成。
注意：我使用字段名称 PageNum 而不是 Page，因为这似乎会在打印预览期间导致 SubReport 绑定出现问题...可能是因为 Page 是报表的现有变量/函数的名称。