CGI::Application，隐藏的表单值被覆盖

Question

我正在查看CGI::Application 的基本示例，但是当我尝试添加第三种模式时，查询对象似乎拒绝使用我提供的值。

webapp.cgi：

#!/usr/bin/perl 
  use webapp;
  my $webapp = WebApp->new();
  $webapp->run();

webapp.pm:

package WebApp;
use base 'CGI::Application';

sub setup {
    my $self = shift;
    $self->start_mode('mode1');
    $self->mode_param('rm');
    $self->run_modes(
        'mode1' => 'do_stuff',
        'mode2' => 'do_more_stuff',
        'mode3' => 'do_something_else'
        );
}


sub do_stuff {
    my $self = shift;
    my $q = $self->query();

    my $output = '';
    $output .= $q->start_html(-title => 'Widget Search Form');
    $output .= $q->start_form();
    $output .= $q->textfield(-name => 'widgetcode');
    $output .= $q->hidden(-name => 'rm', -value => 'mode2');
    $output .= $q->submit();
    $output .= $q->end_form();
    $output .= $q->end_html();

    return $output;
}

sub do_more_stuff {
        my $self = shift;
        my $q = $self->query();
        my $widgetcode = $q->param("widgetcode");
        my $output = '';
        $output .= $q->start_html(-title => 'List of Matching Widgets');    
        $output .= $q->start_form();
        $output .= $q->textfield(-name => 'widgetcode');
        $output .= $q->hidden(-name => 'rm', -value => 'mode3'); 
                                                     # ^^^^^^ 
                                                     # this value is being ignored
        $output .= $q->submit();
        $output .= $q->end_form();      
        $output .= $q->end_html();

        return $output;
}

sub do_something_else {
        my $self = shift;
        my $q = $self->query();
        my $widgetcode = $q->param("widgetcode");
        my $output = '';
        $output .= $q->start_html(-title => 'Widgets details');  
        $output .= $q->start_form();
        $output .= $q->textfield(-name => 'widgetcode');
        $output .= $q->hidden(-name => 'rm', -value => 'mode4');
        $output .= $q->submit();
        $output .= $q->end_form();
        $output .= $q->end_html();
        return $output;
}

1;

所以加载第一页（模式1）工作正常，它给了我表单，我可以提交它并到达第二页（模式2），但我无法到达模式3，因为rm参数正在设置为“mode2”，尽管正如您在上面看到的那样，我将其设置为“mode3”。这意味着我再次被送回模式 2。我可以将rm 更改为rm2 或其他内容，然后获取正确的值，但这显然没有帮助，因为rm 变量是用于设置模式的。

我没有使用 CGI.pm（它提供 query 对象）的经验，正如您所知，我才刚刚开始学习 CGI::Application，所以我不知道发生了什么或者如何解决这个问题。

Answer 1

看来perlmonks有智慧：Hidden fields using CGI

您可以使用 -override 参数强制它使用默认值。

在我的情况下将按如下方式使用：

$output .= $q->hidden(-name => 'rm', -value => 'mode3' , -override => 1);

希望对通过搜索找到此问题的人有所帮助，因为这根本不明显。

Answer 2

是的，hidden 方法似乎将使用当前表单值（如果存在）而不是您指定的默认值。在使用?rm=mode2 访问视图时，可以使用以下代码观察到这一点：

$output .= $q->hidden(-name => 'rm', -value => 'mode3'); # Prints mode2
$q->param('rm' => 'mode3');
$output .= $q->hidden(-name => 'rm'); # Print mode3

如您所见，最好的解决方案是使用 CGI #Form Elements 中记录的覆盖标志

$output .= $q->hidden(-name => 'rm', -value => 'mode3', -override => 1); # Print mode3