【问题标题】:Prolog: How does delete predicate supply even the beginning of the listProlog:删除谓词如何甚至在列表的开头提供
【发布时间】:2018-05-08 15:40:17
【问题描述】:

我当然误解了 Prolog 的工作原理。这个问题很具体,尽管我正在寻找解释而不是编程问题的直接解决方案;一个“如何”的问题,而不是一个“给我代码”的问题。

这是我要询问的 Prolog 删除谓词的定义。

delete(A, [A|B], B).  
delete(A, [B, C|D], [B|E]) :-  
    delete(A, [C|D], E).  

我的误解是,在我看来,像

这样的电话
delete(a, [3,a,b,c,d], X).  

应该成功返回[3,b,c,d](确实如此),但是像

这样的调用
delete(a,[1,2,3,a,b,c,d], X)  

应该无法返回解决方案。然而,后一个调用实际上返回了一个很好的解决方案[1,2,3,b,c,d]。

在我看来是这样的原因如下。 (我认为我们现在越来越接近我无法理解的关于 Prolog 的内容。)参考定义的这一部分,

delete(A, [B, C|D], [B|E]) . . . 

看起来只有头部(即C)之前的单个元素(即B)将包含在响应中。这就是为什么我无法理解的原因

delete (a, [1,2,3,a,b,c,d], X)

设法返回一个答案,其中不仅包括3,还包括1 和2,作为解决方案列表的一部分,但确实如此(如[1,2,3,b,c,d])。谁能解释 Prolog 在这个非常具体的场景中如何处理列表,以说明为什么它认为1 和2 是解决方案的一部分,而不仅仅是3?非常感谢。

【问题讨论】:

    标签: prolog


    【解决方案1】:

    让我们看看有问题的查询会发生什么:

    ?- delete(a,[1,2,3,a,b,c,d], X).
    

    由于a和1不能统一,所以第一条规则失效。但是,第二条规则与A=a、B=1、C=2 和D=[3,a,b,c,d] 匹配。因此,递归目标被称为:

    delete(a,[2|[3,a,b,c,d]],E)
    

    同样,第一条规则不匹配,因为a 与2 不同。第二条规则再次成功,这次是A=a、B=2、C=3 和D=[a,b,c,d]。因此,递归调用:

    delete(a,[3|[a,b,c,d]],E)
    

    再一次,第一条规则失败,第二条规则成功,A=a、B=3、C=a 和 D=[b,c,d]。因此,递归调用:

    delete(a,[a|[b,c,d]],E)
    

    现在,在第一条规则的头部,a=a 已成功统一,因此该规则以A=a、B=[b,c,d] 成功。回到递归,这会产生:

    E=[b,c,d], B=3 therefore [B|E]=[3|[b,c,d]]=[3,b,c,d] 
    
    E = [3,b,c,d], B=2 therefore [B|E]=[2|[3,b,c,d]]=[2,3,b,c,d] 
    
    E = [2,3,b,c,d], B=1 therefore [B|E]=[1|[2,3,b,c,d]]=[1,2,3,b,c,d] 
    

    所以 Prolog 告诉你,确实有一个解决方案:

    ?- delete(a,[1,2,3,a,b,c,d], X).
    X = [1, 2, 3, b, c, d]
    

    现在你按 ;

    询问是否有其他解决方案
    ?- delete(a,[1,2,3,a,b,c,d], X).
    X = [1, 2, 3, b, c, d] ;
    

    Prolog 回到开放选择点并遵循递归规则直到D=[]。第一条规则的下一次递归调用失败,因为[]=[A|B] 无法统一。第二条规则也失败了,因为[]=[B,C|D]也不能统一。所以 Prolog 尽职尽责地报告,没有更多的解决方案:

    ?- delete(a,[1,2,3,a,b,c,d], X).
    X = [1, 2, 3, b, c, d] ;
    false.
    

    【讨论】:

    • 谢谢。对于未来的读者:关于“通过递归返回”的部分特别有用。
    【解决方案2】:

    作为背景的一小部分,我们可以考虑由两个“构造函数”组成的单链表:[],空列表和[H|T],其中H 是某种值存在于列表的头部和T,尾部,H 之后剩余的列表。

    这里有两个子句。第一个是这样的:

    delete(A, [A|B], B).
    

    我可能会以delete(Head, [Head|Tail], Tail) 的方式对此进行一些不同的构架。这是启用统一的子句,例如:

    ?- delete(3, [3,a,b,c,d], X).
    X = [a, b, c, d] 
    

    这是可行的,因为[H|T]=[3,a,b,c,d] 将统一H=3 和T=[a,b,c,d]。试试看。

    现在让我们花点时间思考一下 Prolog 是如何选择子句的。在每一步,Prolog 本质上都在尝试统一。因此,当出现delete(a, [1,2,3,a,b,c,d], X) 时,Prolog 继续尝试将delete(H, [H|T], T) 与delete(a, [1,2,3,a,b,c,d], X) 统一起来。这不会成功,因为 a != 1。所以 Prolog 再次尝试使用第二个子句,我们发现自己在这里:

    delete(A, [B, C|D], [B|E]) :-  
        delete(A, [C|D], E).  
    

    现在以示例为例,Prolog 将尝试将子句的头部与delete(A=a, [B=1,C=2|D=[3,a,b,c,d]], [B=1|E]) 统一起来。之所以成功,是因为A 不能等于 a、B 不能等于 1、C 不能等于 2、D 不能等于 [3,a,b,c,d] 并没有什么特别的原因。所以现在 Prolog 前进到delete(A, [C|D], E),它会尝试调用delete(a, [2,3,a,b,c,d], E)。如果你在你的 REPL 中启用trace,你会看到这个在工作:

    ?- trace.
    true.
    
    [trace]  ?- delete(a, [1,2,3,a,b,c,d], X).
       Call: (8) delete(a, [1, 2, 3, a, b, c, d], _3240) ? creep
       Call: (9) delete(a, [2, 3, a, b, c, d], _3498) ? creep
    

    您在第二次调用中看到,Prolog 现在有兴趣查找delete(a, [2,3,a,b,c,d], _4120),这是一个新变量,而不是前一次调用中的变量。我可以向你保证,同样的事情会在新的事情发生之前再发生几次。

       Call: (9) delete(a, [2, 3, a, b, c, d], _3498) ? creep
       Call: (10) delete(a, [3, a, b, c, d], _3510) ? creep
    

    但是,在下一次调用时,可以激活第一个子句:

       Call: (11) delete(a, [a, b, c, d], _3522) ? creep
       Exit: (11) delete(a, [a, b, c, d], [b, c, d]) ? creep
    

    这一次,变量被统一了。这是因为您的第一个子句是基本情况。现在回头看你的定义,你可以看到第二个子句中的第三个参数是[B|E],这意味着当B和E都被统一时,它将获得一个值。因此,跟踪的其余部分是该子句的退出,该变量已与某物统一。每次,所发生的只是 B 在递归调用被附加到结果之前从列表中删除:

       Exit: (10) delete(a, [3, a, b, c, d], [3, b, c, d]) ? creep
       Exit: (9) delete(a, [2, 3, a, b, c, d], [2, 3, b, c, d]) ? creep
       Exit: (8) delete(a, [1, 2, 3, a, b, c, d], [1, 2, 3, b, c, d]) ? creep
    X = [1, 2, 3, b, c, d] .
    

    你有它。

    【讨论】:

    • “B 在递归调用附加到结果之前被从列表中删除......”那是我没有得到的部分。可以这么说,Prolog 会自动尝试它在下降过程中传递的内容。谢谢。 (两个答案都很棒;这个措辞非常中肯。)
    • @davo 不客气。当然,如果说 Prolog 在其中一些变量被绑定之前建立了这些变量之间的关系,然后它们被绑定,那就更真实了。同样的技巧是允许它使用差异列表附加 O(1) 链表。
    猜你喜欢
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2022-01-16
    • 1970-01-01
    • 1970-01-01
    • 2017-09-29
    相关资源
    最近更新 更多