Prolog 解包列表谓词

Question

我试图创造一些像这样工作的东西：

?- unpacking([[1], [1,2], [3]], Lst1, NewLst).
NewLst=[1,3]

我是这样写的：

unpacking([], Lst1, Lst1).
unpacking([[H]|T], Lst1, NewLst):-
    append([H], Lst2),
    unpacking(T, Lst2, NewLst).
unpacking([_|T], Lst1, NewLst):-
    unpacking(T, Lst1, NewLst).

我知道我做错了什么。我从 Prolog 开始，所以需要从我的错误中吸取教训 :)

Answer 1

你的意思可能是：

unpacking([], []).
unpacking([[E]|T], [E|L]) :-
   unpacking(T, L).
unpacking([[]|T], L) :-
   unpacking(T, L).
unpacking([[_,_|_]|T], L) :-
   unpacking(T, L).

有更简洁的方法来编写这个 - 而且也更有效。

Answer 2

这个呢：

%?-unpacking([[a,b,c],[a],[b],[c,d]],Items).
unpacking(Lists,Items):-
 my_tpartition(length_t(1),Lists,Items,Falses).

my_tpartition(P_2,List,Ts,Fs) :- my_tpartition_ts_fs_(List,Ts,Fs,P_2).

my_tpartition_ts_fs_([],[],[],_).
my_tpartition_ts_fs_([X|Xs0],Ts,Fs,P_2) :-
 if_(call(P_2,X), (X=[NX],Ts = [NX|Ts0], Fs = Fs0),
                (Ts = Ts0,     Fs = [X|Fs0])),
my_tpartition_ts_fs_(Xs0,Ts0,Fs0,P_2).

length_t(X,Y,T):-
 length(Y,L1),
 =(X,L1,T).

这是基于Most general higher-order constraint describing a sequence of integers ordered with respect to a relation

* 更新*

你可以改成

length_t(X,Y,T):-
 L1 #=< X,
 fd_length(Y,L1),
 =(X,L1,T),!.

length_t(_X,_Y,false).

fd_length(L, N) :-
 N #>= 0,
 fd_length(L, N, 0).

fd_length([], N, N0) :-
 N #= N0.
fd_length([_|L], N, N0) :-
 N1 is N0+1,
 N #>= N1,
 fd_length(L, N, N1).

给予：

?-unpacking([[1],[2,3],[4],[_,_|_]],U).
U= [1,4].

但是：

?-unpacking([X],Xs).
X = Xs, Xs = [].

Answer 3

基于@coder的解决方案，我自己尝试使用if_和DCGs：

one_element_([], true).
one_element_([_|_],false).

one_element([], false).
one_element([_|Xs], T) :-
    one_element_(Xs, T).

f([]) -->
    [].
f([X|Xs]) -->
    { if_(one_element(X), Y=X, Y=[]) },
    Y,
    f(Xs).

unpack(Xs,Ys) :-
    phrase(f(Xs),Ys).

我只尝试了大约 30 秒，但查询：

?- Xs = [[] | Xs], unpack(Xs,Ys).
?- Xs = [[_] | Xs], unpack(Xs,Ys).
?- Xs = [[_, _ | _] | Xs], unpack(Xs,Ys).

没有因堆栈溢出而停止。在我看来，关键的应该是最后一个查询，但显然，SWI Prolog 设法优化：

?- L = [_,_|_], one_element(L,T).
L = [_3162, _3168|_3170],
T = false.

编辑：我改进了解决方案并尝试使用参数索引。根据SWI Manual，如果空列表[] 和非空列表[_|_] 之间存在大小写区别，则会发生索引。我重写了one_element，使它完全做到了这一点，并用辅助谓词one_element_重复了这个技巧。现在one_element 又是纯的了，我们不再丢失解决方案：

?- unpack([A,B],[]).
A = [_5574, _5580|_5582],
B = [_5628, _5634|_5636] ;
A = [_5574, _5580|_5582],
B = [] ;
A = [],
B = [_5616, _5622|_5624] ;
A = B, B = [].

但是

?- unpack([[a,b,c],[a],[b],[c,d]],Items).
Items = [a, b].

仍然是确定性的。我没有在其他 Prologs 中尝试过这个解决方案，它可能缺少索引，但对于 SWI 来说，这是一个解决方案。

更新：显然 GNU Prolog 不会在循环列表上进行这种索引和溢出：

| ?- Xs = [[] | Xs], unpack(Xs,Ys).

Fatal Error: global stack overflow (size: 32770 Kb, reached: 32768 Kb, environment variable used: GLOBALSZ)

Answer 4

经过一番思考，这是我使用if_/3的实现：

unpacking(L,L1):-if_( =(L,[]), L1=[], unpack(L,L1)).

unpack([H|T],L):-if_(one_element(H), (H = [X],L=[X|T1],unpacking(T,T1)), unpacking(T,L)).

one_element(X, T) :-
   (  var(X) ->(T=true,X=[_]; T=false,X=[])
    ;  X = [_] -> T = true
    ;  X \= [_] -> T = false).

一些测试用例：

?- unpacking([Xss],[]).

Xss = [].

?- unpacking([[1],[2,3],[4],[_,_|_]],U).
U = [1, 4].

?- unpacking([[1],[2,3],[4]],U).
U = [1, 4].

?- unpacking([[E]],[1]), E = 2.
false.

?- unpacking(non_list, []).
false.

?- unpacking([Xs],Xs).
Xs = [_G6221] ;
Xs = [].

---

更新
为了解决@false 在评论中提到的情况，我们可以定义：

one_element([],false).
one_element([_],true).
one_element([_,_|_],false).

但这留下了一些选择点......

Answer 5

一种方法是使用 findall 我不认为这是赏金的目的；）

unpacking(Lists,L1):-
   findall(I,(member(M,Lists),length(M,1),M=[I]),L1).

or 

unpacking2(Lists,L1):-
   findall(I,member([I],Lists),L1).