在 vb.net 中裁剪图像时处理内存泄漏

Question

当我将图像分解为子图像时，我不断收到系统内存不足错误。没有什么太花哨的事情，只是将图像分成一堆较小的图像。这是我的代码：

Dim counterrr As Integer = 0
Dim sorucedir As String
Dim tardir As String
sorucedir = "C:\somedir\"
tardir = "C:\otherdir\"
Dim di2 As New DirectoryInfo(sorucedir)
Dim fiArr2 As FileInfo() = di2.GetFiles()
Dim fri2 As FileInfo
Dim hh As Integer
Dim ww As Integer
hh = 995 'height of source images
ww = 1080 'width of source images
Dim sizestepX As Integer = 180
Dim stepsizeY As Integer = 239
For i = 0 To ww - 1 Step sizestepX
    For j = 0 To hh - 1 Step stepsizeY
        For Each fri2 In fiArr2
            Dim BM2 As Bitmap
            BM2 = Image.FromFile(fri2.FullName)
            ''Threading.Thread.Sleep(3000)
            'bm2 = Image.FromFile(fri2.FullName)
            Dim BM3 As Bitmap
            Dim rect As New Rectangle(i, j, sizestepX, stepsizeY)
            BM3 = BM2.Clone(rect, Imaging.PixelFormat.DontCare)
            counterrr += 1
            Dim ss As String
            ss = tardir & counterrr & ".png"
            BM3.Save(ss, Imaging.ImageFormat.Png)
            BM3 = Nothing
        Next
    Next
Next

创建少至 6 个图像后出现错误（创建第 7 个图像时发生）。抛出错误的行是这样的：

BM3 = BM2.Clone(rect, Imaging.PixelFormat.DontCare)

如何修改我的代码，使它们的对象被正确处理（？），这样它们就不会泄漏内存。

Answer 1

Bitmap 类以及许多其他 GDI+ 类都实现了IDisposable，因为它们持有需要释放的底层 GDI 对象句柄。每个进程由操作系统限制为最大 GDI 对象数，通常为 10,000。您可以在 Windows 任务管理器中查看每个进程的活动 GDI 对象总数。要解决您的问题，您需要在您创建的每个Bitamp 对象超出范围之前手动调用Dispose 方法，或者您需要将每个Bitmap 变量声明包装在Using 块中（所以它会为你调用Dispose）。例如：

Using BM2 As Bitmap = Image.FromFile(fri2.FullName)
    Dim rect As New Rectangle(i, j, sizestepX, stepsizeY)
    Using BM3 As Bitmap = BM2.Clone(rect, Imaging.PixelFormat.DontCare)
        counterrr += 1
        Dim ss As String
        ss = tardir & counterrr & ".png"
        BM3.Save(ss, Imaging.ImageFormat.Png)
    End Using
End Using

注意：在最后将 BM3 变量设置为 Nothing 是没有意义的，就像你正在做的那样。这与任何事情无关。