是否可以让数据透视表切片器从大到小排序？

Question

我创建了一个带有增益和损失的新表。我的目标是从最大到最小对表格进行增益排序，从最小到最大损失排序。我尝试了一些 vba，但无法对值进行排序。

Sub Macro1() 

Dim wb As Workbook 
Dim ws As Worksheet 
Dim targetTable As ListObject 
Set wb = ThisWorkbook 
Set ws = wb.Worksheets("Project Dash") 

If Worksheets("Project Dash").SlicerCaches("Slicer_Gains__Losses") .SlicerItems("Gai‌​ns").Selected = True Then 

    ActiveSheet.PivotTables("ProjectGain20").PivotFields("Projec‌​t").AutoSort _ xlDescending, "Sum of Work Variance", ActiveSheet.PivotTables("ProjectGain20"). _ PivotColumnAxis.PivotLines(1), 1 

End If 

End Sub

Answer 1

下面是一个使用选项按钮来对后备表进行排序的示例。切片器旨在过滤您的数据而不是对其进行排序。当您添加表单控件单选/选项按钮时，您需要编辑文本，如我的图像所示，然后右键单击每个按钮并将每个按钮与宏 CheckOptions 相关联。这里被排序的字段是[Value1]，您可以根据需要进行更改。如图所示，您的数据需要设置为表格。

我使用了@L42 的建议来检查哪个选项按钮调用了宏。

排序顺序枚举给出here。

进入标准模块的代码：

Option Explicit

Public Sub CheckOptions()                        

    Dim wb As Workbook
    Dim ws As Worksheet
    Dim targetTable As ListObject

    Set wb = ThisWorkbook
    Set ws = wb.Worksheets("Sheet1") 'Change as appropriate
    Set targetTable = ws.ListObjects("Table1")

    Select Case Application.Caller

    Case "Option Button 1"

        SortTable targetTable, 2

    Case "Option Button 2"

        SortTable targetTable, 1

    End Select
End Sub

Private Sub SortTable(ByRef targetTable As ListObject, ByVal myOrder As Byte) 'https://msdn.microsoft.com/en-us/vba/excel-vba/articles/xlsortorder-enumeration-excel

    With targetTable.Sort

        .SortFields.Clear

        .SortFields.Add _
        Key:=Range("Table1[[#All],[Value1]]"), SortOn:=xlSortOnValues, order:= _
                   myOrder, DataOption:=xlSortNormal

        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply

    End With

End Sub