最小和最大函数中的类型错误

Question

我正在做一个 haskell 项目，并且有一个 minmax 函数，它可以获取列表的最小值和最大值，并以元组对的形式返回它们，如下所示：

λ> minmax [1,2,3]
(1,3)
λ> minmax [4,2,5,9]
(2,9)

现在我正在实现一个递归循环的用户输入列表，直到输入取消输入，然后列表完成，然后需要利用我的 minmax 函数，我遇到的问题是它显然不是同一类型完成后的简单列表，因为它会引发类型错误。

minmax :: (Ord a) => [a] -> (a,a)
minmax [] = error "Null"
minmax (x:xs) = (minimum (x:xs), maximum (x:xs))

convertIO :: IO Int
convertIO = do
    line <- getLine
    return (read line :: Int)

minmaxlist :: IO [Int]
minmaxlist = do
    number <- convertIO
    if(number /= 0)
        then (do 
            int_list <- minmaxlist
            return (minmax (number:int_list)))
    else return []

向我抛出了这个特定的错误：

Couldn't match expected type `[Int]' with actual type `(Int, Int)'

虽然整数列表正是我通过 (number:int_list) 传递的内容，但如果我确实将整数列表传递给它，它会返回元组。为什么它在这里向我抛出错误？是不是跟 IO 类型有关系？

Answer 1

你的想法是个好主意——minmax 和你产生IO [Int] 的方式似乎都是合理的——我只想将minmax 的应用程序从列表生成中全部排除：

module Main where

minmax :: (Ord a) => [a] -> (a,a)
minmax [] = error "Null"
minmax (x:xs) = (minimum (x:xs), maximum (x:xs))

convertIO :: IO Int
convertIO = do
    line <- getLine
    return (read line :: Int)

ioInts :: IO [Int]
ioInts = do
    number <-convertIO
    if number /= 0
      then do 
        int_list <- ioInts
        return (number:int_list)
      else return []

minmaxIO :: IO (Int,Int)
minmaxIO = do
  list <- ioInts
  return $ minmax list

main :: IO ()
main = do
  val <- minmaxIO
  print val

您可以使用像 (<$>) 这样的运算符使这一切变得更短，但我认为您更喜欢使用 do 表示法

如你所见，我刚刚添加了另一个IO 计算minmaxIO，它将minmax 应用于ioInts 生成的列表（我从你的minmaxlist 重命名） - 如果基本上仍然是你的其他东西

Answer 2

minmaxlist :: IO [Int] 声明 minmaxlist 是一个返回 Int 列表的 IO 操作。但是，它会尝试返回 minmax（在 return (minmax (number:int_list))) 中）的结果，其类型为 (Int, Int)。

那么，您希望minmaxlist 返回什么？

Answer 3

你非常接近 - 不要使用元组，而是返回一个列表

minmax :: (Ord a) => [a] -> [a]
minmax [] = error "Null"
minmax xs = [minimum xs, maximum xs]