在 Excel 中一次设置多个切片器

Question

我有一个带有两个具有完全相同切片器的数据透视表的工作簿。我正在使用 VBA 脚本来同步两个切片器。我将它们命名为“Slicer_xxxx_Master”，另一个为“Slicer_xxxx_Slave”。

下面的代码可以正常工作，除了有很多选项的切片器。由于它会一一设置切片，因此它会一遍又一遍地重新过滤数据透视表，直到设置了所有需要的切片。

有没有一种方法可以将所有切片项的值收集到一个数组中，然后一次性设置 Slave 切片器的值？

Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable)
Application.ScreenUpdating = False

Dim sC As SlicerCache
Dim sC_Slave As SlicerCache
Dim SL As SlicerCacheLevel
Dim sI As SlicerItem
Dim sI_Slave As SlicerItem


For Each sC In ActiveWorkbook.SlicerCaches
    If InStr(1, sC.Name, "Master") Then
        Set sC_Slave = ThisWorkbook.SlicerCaches(Replace(sC.Name, "Master", "Slave"))
        For Each sI In sC.SlicerItems
            If sI.Name <> ("(blank)") Then
                Set sI_Slave = sC_Slave.SlicerItems(sI.Name)
                If sI_Slave.Selected <> sI.Selected Then
                    sI_Slave.Selected = sI.Selected
                End If
            End If
        Next
    End If
Next

Application.ScreenUpdating = True
End Sub

Answer 1

我只在从数据透视表上使用了 ManualUpdate = FALSE 和断开/重新连接功能，情况比以前好得多。谢谢杰弗里！

Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable)
Application.EnableEvents = False
Application.ScreenUpdating = False

Dim sC As SlicerCache
Dim sC_Slave As SlicerCache
Dim sI As SlicerItem
Dim sI_Slave As SlicerItem
Dim wS As Worksheet
Dim pT As PivotTable

Set wS = ThisWorkbook.Worksheets("Totals Pivot")
wS.PivotTables("TotalsPivot").ManualUpdate = True

For Each sC In ThisWorkbook.SlicerCaches
    If InStr(1, sC.Name, "Master") Then
        Set sC_Slave = ThisWorkbook.SlicerCaches(Replace(sC.Name, "Master", "Slave"))
        sC_Slave.PivotTables.RemovePivotTable ("TotalsPivot")

        For Each sI In sC.SlicerItems
            Set sI_Slave = sC_Slave.SlicerItems(sI.Name)
            If sI_Slave.Selected <> sI.Selected Then
                sI_Slave.Selected = sI.Selected
            End If
        Next

        sC_Slave.PivotTables.AddPivotTable wS.PivotTables("TotalsPivot")
    End If
Next

wS.PivotTables("TotalsPivot").ManualUpdate = False

Application.EnableEvents = True
Application.ScreenUpdating = True
End Sub

Answer 2

如果您使用的是 Excel 2013 或更高版本，则可以将每个数据源添加到 DataModel，然后只需定义它们之间的关系。然后一个切片器将统治它们，这将比将事物分开要快得多，因为 OLAP/PowerPivot PivotTables 只需输入一个数组 (VisiblieItemsList)，它可以一次性告诉它们要显示什么。

但是，如果您想将事情分开，那么在更改 PivotItems 的状态时加快速度（无论是直接还是通过切片器），您至少应该将每个数据透视表的 .ManualUpdate 属性设置为 TRUE，以停止每次更改 SlicerItem 后数据透视表都会更新。

鉴于我们在此处处理 Slicers，您可以通过执行以下操作（并将 Pivots 的 .ManualUpdate 属性设置为 FALSE）来真正让例程超速运行：

1. 暂时断开切片器与主从设备的连接
2. 像上面那样遍历切片器缓存
3. 将切片器重新连接到主设备和从设备。

这又快得多的原因是切片器的实现方式似乎存在一个错误，因为每当您更改切片器项目的状态时，它都会导致数据透视表更新...即使您已设置将 PivotTables .ManualUpdate 设置为 true，正如我在 here 写的一篇博文中所述

我在编程数据透视表here 时写了一篇帖子覆盖瓶颈，这可能会很有趣，以及在 SO 上可能值得一看的一些问题的答案，例如 this one。