在 Junit 或 Groovy/Spock 测试中测试匿名类

Question

我正在尝试在 Groovy/Spock 中编写单元测试，并且必须测试以下代码。

public class ClassA {
    @Inject
    private ClassB classB;

    @Inject
    private ClassC classC;

    @Inject
    private ClassD classD;

    public void update(final int a, final Map<String, Object> b) {
        classB.executeCommand(classC.callToMethodInClassC(), new InterfaceE<Void>() {
            @Override
            public Void execute() {
                classD.update(a, b);
                return null;
            }
        });
    }
}

现在，当我编写测试代码时，我无法到达classD.update(a, b); 行。我知道如何为 ClassB、ClassC、ClassD 注入模拟/真实对象，但无法达到该声明。请帮忙。

注意： ClassA.update() & ClassD.update() 除了签名匹配外，没有任何关系。

Answer 1

像这样模拟你的 classB：

Mock(ClassB) {
    executeCommand(_, _) >> { c, e -> e.execute() }
}

即为 ClassB 的 executeCommand 方法提供一个模拟实现，它实际上调用了 interfaceE 的 execute 方法。

编辑：完整的工作示例：

import spock.lang.Specification

class TestMeSpec extends Specification {

    def "my test"() {
        def b = Mock( ClassB ) {
            executeCommand( _, _ ) >> { c, e -> e.execute() }
        }
        def c = Mock( ClassC )
        def d = Mock( ClassD )

        def a = new ClassA( classB: b, classC: c, classD: d )

        when:
        a.update( 0, [ : ] )

        then:
        1 * d.update( 0, [ : ] )
    }
}

class ClassA {
    ClassB classB
    ClassC classC
    ClassD classD

    void update( final int a, final Map<String, Object> b ) {
        classB.executeCommand( classC.callToMethodInClassC(), new InterfaceE<Void>() {
            @Override
            Void execute() {
                classD.update( a, b )
            }
        } )
    }
}

class ClassB {
    void executeCommand( c, InterfaceE e ) {
        println "REAL CLASS B executCommand() METHOD RUNNING"
    }
}

class ClassC {
    def callToMethodInClassC() {}
}

class ClassD {
    void update( a, b ) {
        println "REAL CLASS D update() method called with $a and $b"
    }
}

interface InterfaceE<T> {
    T execute()
}