测试使用 System.console() 的 Groovy 类

Question

我有一个 groovy 脚本，它使用 readline 方法通过 java.io.console 对象向用户询问一些问题。此外，我用它来询问密码（用于设置 HTTPS）。我如何使用 Spock 对这段代码进行单元测试？目前它抱怨该对象是Java最终对象并且无法测试。显然，我不是第一个尝试这个的人，所以我想问一下。

代码草图如下所示：

class MyClass {

   def cons

   MyClass() {
     cons = System.console()
   }

   def getInput = { prompt, defValue ->
     def input = (cons.readLine(prompt).trim()?:defValue)?.toString()
     def inputTest = input?.toLowerCase()
     input
   }
}

我希望单元测试能够测试是否可以返回一些模拟响应以及是否可以返回默认值。注意：这是简化的，所以我可以弄清楚如何进行单元测试，getInput 方法中还有更多代码需要测试，但是一旦我清除了这个障碍，应该没问题。

根据 akhikhl 的回答编辑 按照建议，我做了一个简单的界面：

interface TestConsole {
    String readLine(String fmt, Object ... args)
    String readLine()
    char[] readPassword(String fmt, Object ... args)
    char[] readPassword()
}

然后我尝试了这样的测试：

def "Verify get input method mocking works"() {

    def consoleMock = GroovyMock(TestConsole)
    1 * consoleMock.readLine(_) >> 'validResponse'

    inputMethods = new MyClass()
    inputMethods.cons = consoleMock

    when:
    def testResult = inputMethods.getInput('testPrompt', 'testDefaultValue')
    then:
    testResult == 'validResponse'
}

我选择不更改构造函数，因为我不喜欢仅仅为了测试而更改我的实际代码。幸运的是，Groovy 让我只用一个“def”来定义控制台，所以我所做的工作正常。

问题是上面的不行！！！我无法抗拒——这不合逻辑！ Spock 在 GroovyMockMetaClass 的某个地方“迷路”了。如果我更改代码中的一行和测试中的一行，它就可以工作。

代码更改：

From:
    def input = (cons.readLine(prompt).trim()?:defValue)?.toString()
To: (add the null param)
    def input = (cons.readLine(prompt, null).trim()?:defValue)?.toString()

测试更改：

From:
    1 * consoleMock.readLine(_) >> 'validResponse'
To: (again, add a null param)
    1 * consoleMock.readLine(_, null) >> 'validResponse'

然后测试终于成功了。这是 Spock 中的一个错误，还是我只是在左场？我不介意在测试工具中需要做任何可能需要做的事情，但是必须修改代码才能完成这项工作真的非常糟糕。

Answer 1

你是对的：因为 Console 类是最终的，它不能被扩展。因此，解决方案应该朝另一个方向发展：

1. 创建新类 MockConsole，不是从 Console 继承的，而是具有相同的方法。

2. 这样改变MyClass的构造函数：

   MyClass(cons = null) { this.cons = cons ?: System.console() }

3. 在 spock 测试中实例化 MockConsole 并将其传递给 MyClass 构造函数。

update-201312272156

我和 spock 玩了一会儿。模拟“readLine（String fmt，Object ... args）”的问题似乎特定于可变参数（或最后一个参数是一个列表，这与 groovy 相同）。我设法将问题减少到以下情况：

定义一个接口：

interface IConsole {
  String readLine(String fmt, Object ... args)
}

定义测试：

class TestInputMethods extends Specification {

  def 'test console input'() {
    setup:
    def consoleMock = GroovyMock(IConsole)
    1 * consoleMock.readLine(_) >> 'validResponse'

    when:
    // here we get exception "wrong number of arguments":
    def testResult = consoleMock.readLine('testPrompt')

    then:
    testResult == 'validResponse'
  }
}

此测试变体失败，异常“参数数量错误”。特别是，spock 认为 readLine 接受 2 个参数并忽略了第二个参数是 vararg 的事实。证明：如果我们从 IConsole.readLine 中删除“Object ... args”，则测试成功完成。

这里是解决这个（希望是暂时的）问题的解决方法：将对 readLine 的调用更改为：

def testResult = consoleMock.readLine('testPrompt', [] as Object[])

然后测试成功完成。

我还针对 spock 1.0-groovy-2.0-SNAPSHOT 尝试了相同的代码 - 问题是一样的。

update-201312280030

可变参数的问题解决了！非常感谢@charlesg，他回答了我的相关问题：Spock: mock a method with varargs

解决方案如下：将 GroovyMock 替换为 Mock，然后正确解释 varargs。