在 Haskell 中有条件地处理 IO 的惯用方法

Question

我正在用 Haskell 编写一个小 shell 脚本，它可以接受一个可选参数。但是，如果参数不存在，我想从标准输入中获取一行来请求一个值。

在 Haskell 中执行此操作的惯用方式是什么？

#!/usr/bin/env runhaskell

import Control.Applicative ((<$>))
import Data.Char (toLower)
import IO (hFlush, stdout)
import System.Environment (getArgs)

main :: IO ()
main = do args <- getArgs
          -- here should be some sort of branching logic that reads
          -- the prompt unless `length args == 1`
          name <- lowerCase <$> readPrompt "Gimme arg: "
          putStrLn name

lowerCase = map toLower

flushString :: String -> IO ()
flushString s = putStr s >> hFlush stdout

readPrompt :: String -> IO String
readPrompt prompt = flushString prompt >> getLine

哦，如果有办法通过Control.Applicative 或Control.Arrow 来实现，我想知道。我对这两个模块非常感兴趣。

谢谢！

Answer 1

main :: IO ()
main = do args <- getArgs
          name <- lowerCase <$> case args of
            [arg] -> return arg
            _     -> readPrompt "Gimme arg: "
          putStrLn name

Answer 2

这不适合您的特定用例，但问题标题让我立即想到了Control.Monad 中的when。直接来自the docs：

when :: Monad m => Bool -> m () -> m ()

单子表达式的条件执行。

例子：

main = do args <- getArgs
          -- arg <- something like what FUZxxl did..
          when (length args == 1) (putStrLn $ "Using command line arg: " ++ arg)
          -- continue using arg...

您也可以以类似的方式使用when 的表弟unless。