将唯一年份从日期添加到组合框

Question

我在一列中有一个日期列表。我想将这些日期的唯一年份添加到用户窗体上的组合框。

用户表单用于根据用户选择的月份和年份生成报告。我只想要有条目的年份。所以当它进入 2014 年时，当第一个条目进入 2014 年的电子表格时，报告生成器可以选择。

Dim c As Range, Coll As New Collection
On Error Resume Next
For Each c In Sheets("Permits & Access").Range(ActiveSheet.Range("L3"), Sheet.Range    ("L3").End(xlDown))
Coll.Add c.Value, c.Value
Next c
On Error GoTo 0
For Each Item In Coll
cboYear.AddItem Item
Next Item

这是我用来显示唯一日期的代码 sn-p。但我实际上只需要独特的岁月。我知道使用 Year() 方法来提取年份，只是没有任何运气来实现它。

Answer 1

我是这样做的，但改用Dictionary。

Option Explicit
Private Sub UserForm_Initialize()

Dim dict As Object, item As Variant
Dim cel, rng As Range

Set dict = CreateObject("scripting.dictionary")
Set rng = ThisWorkbook.Sheets("Sheet1").Range("A2:A12") 

'--> empty ComboBox1
Me.ComboBox1.Value = ""

'--> sort the range, sorting Collection or Dictionary is a bit complex
rng.Sort Key1:=rng.Cells(1), Order1:=xlAscending, Header:=xlNo, _
    OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, DataOption1:=xlSortNormal 

'--> Test for unique year, add to dictionary
For Each cel In rng
    If Not dict.exists(Format(cel, "yyyy")) Then
        dict.Add Format(cel, "yyyy"), Format(cel, "yyyy")
    End If
Next

'--> Populate ComboBox1 with the unique year
For Each item In dict.items
    Me.ComboBox1.AddItem item
Next

Set dict = Nothing
Set rng = Nothing

End Sub

希望对你有所帮助。