在 Mac 0SX 上使用 x86 汇编程序的 Hello World

Question

我正在尝试在我的 Mac 上进行一些 x86 汇编编程，但无法生成可执行文件。问题似乎出在链接阶段。

helloWorld.s：

.data

    HelloWorldString:
    .ascii "Hello World\n"

.text

.globl _start

_start:
    # load all the arguments for write()
    movl $4, %eax
    movl $1, %ebx
    movl $HelloWorldString, %ecx
    movl $12, %edx
    # raises software interrupt to call write()
    int $0x80

    # call exit()
    movl $1, %eax
    movl $0, %ebx
    int $0x80

组装程序：

as -o helloWorld.o helloWorld.s

链接目标文件：

ld -o helloWorld helloWorld.o

此时我得到的错误是：

ld: could not find entry point "start" (perhaps missing crt1.o) for inferred architecture x86_64

任何关于我做错/遗漏的建议都会非常有帮助。谢谢

Answer 1

您可能会发现使用 gcc 构建比尝试对汇编器和链接器进行微观管理更容易，例如

$ gcc helloWorld.s -o helloWorld

（如果你走这条路，你可能想要将_start 更改为_main。）

顺便说一句，从一个工作的 C 程序开始，并从中研究生成的 asm 可能是有益的。例如

#include <stdio.h>

int main(void)
{
    puts("Hello world!\n");

    return 0;
}

使用gcc -Wall -O3 -m32 -fno-PIC hello.c -S -o hello.S 编译时生成：

    .cstring
LC0:
    .ascii "Hello world!\12\0"
    .text
    .align 4,0x90
.globl _main
_main:
    pushl   %ebp
    movl    %esp, %ebp
    subl    $24, %esp
    movl    $LC0, (%esp)
    call    _puts
    xorl    %eax, %eax
    leave
    ret
    .subsections_via_symbols

您可能需要考虑将其用作您自己的“Hello world”或其他实验性 asm 程序的模板，特别是考虑到它已经构建并运行：

$ gcc -m32 hello.S -o hello
$ ./hello 
Hello world!

最后一条评论：谨防从面向 Linux 的 asm 书籍或教程中获取示例并尝试在 OS X 下应用它们 - 存在重要差异！

Answer 2

试试：

ld -e _start -arch x86_64 -o HelloWorld HelloWorld.S

然后：

./HelloWorld

信息：

-e <entry point>
-arch <architecture>, You can check your architecture by uname -a 
-o <output file>

Answer 3

你好.asm

.data

    HelloWorldString:
    .ascii "Hello World!\n"

.text

.globl start

start:
    ; load all the arguments for write()
    movl $0x2000004, %eax
    movl $1, %ebx
    movq HelloWorldString@GOTPCREL(%rip), %rsi
    movq $100, %rdx
    ; raises software interrupt to call write()
    syscall

    ; call exit()
    movl $0x2000001, %eax
    movl $0, %ebx
    syscall

然后运行：

$ as -arch x86_64  -o hello.o hello.asm
$ ld -o hello hello.o
$ ./hello

这是一个适用于 Mac OS X Mach-0 基于 GNU 的汇编程序的有效解决方案

Answer 4

问题中的代码看起来适用于 32 位 Linux，使用 int $0x80 ABI 和 EBX、ECX、EDX 中的参数。

MacOS 上的 x86-64 代码使用 syscall 指令，其 arg 传递和返回值类似于 与 x86-64 System V ABI for Linux 中记录的内容。它与int $0x80 完全不同，唯一的相似之处是在EAX/RAX 中传递了索书号。但电话号码不同：https://sigsegv.pl/osx-bsd-syscalls/ ORed 与 0x2000000。

Args 进入与函数调用相同的寄存器。 （除了 R10 而不是 RCX。）

另见basic assembly not working on Mac (x86_64+Lion)?和How to get this simple assembly to run?

---

我认为这是另一个答案中建议的更简洁和直观的版本。

OS X 使用start，而不是_start，作为进程入口点。

.data
str:
  .ascii "Hello world!\n"
  len = . - str                  # length = start - end.   . = current position

.text
.globl start
start:
    movl   $0x2000004, %eax
    movl   $1, %edi
    leaq   str(%rip), %rsi  
    movq   $len, %rdx          
    syscall                       # write(1, str, len)

    movl   $0x2000001, %eax 
    movl   $0, %edi
    syscall                       # _exit(0)

通常，当寄存器暗示操作数大小后缀时，您会省略它。并使用xor %edi,%edi 将 RDI 归零。

并使用mov $len, %edx，因为您知道大小小于 4GB，因此更高效的 32 位零扩展 mov-immediate 将起作用，就像您将 RAX 设置为索书号一样。

注意使用 RIP 相对 LEA 将静态数据的地址放入寄存器。 MacOS 上的 x86-64 代码不能使用 32 位绝对寻址，因为您的可执行文件将被映射的基地址高于 2^32。

32 位绝对地址没有重定位类型，因此您不能使用它们。 （而且您需要相对于 RIP，而不是绝对的 64 位，即使它也受支持。）

Answer 5

要在 MacOS 10.15 上组装和链接 @NoOffenceIntended's answer 中的代码，需要进行以下更改：

将.global _start 更改为.global main，并将_start: 更改为main:

要组装和链接代码，请使用：

as -arch x86_64 -o hello.o hello.asm
ld -arch x86_64 -o hello hello.o -lSystem

这是假设正在使用“as”的“Apple clang version 12.0.0”并使用相应的“ld”。