汇编“Hello world”程序分段错误

Question

为什么会出现错误：

分段错误（核心转储）

这是汇编代码：

.intel_syntax noprefix
    
.data

    message: .asciz "Hello World!\n"

.text

.global main

main:
    lea rdi, message
    call printf

    ret

Answer 1

问题

System V ABI 要求您在调用函数之前将堆栈对齐为 16 字节。为了方便起见，ABI 保证“在函数入口时，如果您使用 8 * n（n 是奇数）子堆栈指针，您的堆栈将是 16 字节对齐的”。

如果您不遵循此调用约定，其他库可能会崩溃，因为如果它们需要使用需要特殊对齐的指令（例如 movdqa），则它们无法正确对齐堆栈帧。

解决方案

ammarfaizi2@integral:/tmp/test_asm$ cat test.S
.intel_syntax noprefix
    
.data

    message: .asciz "Hello World!\n"

.text

.global main

main:
    sub rsp, 8
    xor eax, eax
    lea rdi, [rip + message]
    call printf
    add rsp, 8
    ret
ammarfaizi2@integral:/tmp/test_asm$ gcc test.S -o test
ammarfaizi2@integral:/tmp/test_asm$ ./test
Hello World!
ammarfaizi2@integral:/tmp/test_asm$ 

---

推荐

如果你call 一个函数，接下来你要做的是ret，你可以用尾调用来简化代码。它使用jmp 来调用目标函数。如果之前设置过，请确保在跳转之前撤消当前函数堆栈帧。

要支持 PIE 和 PIC，请考虑使用 RIP 相对寻址来访问静态存储。它还提高了安全性。现在的编译器通常默认将目标编译为 PIE。

这部分是使用RIP相对寻址访问静态存储的例子：

lea rdi, [rip + message]

执行

ammarfaizi2@integral:/tmp/test_asm$ cat test.S
.intel_syntax noprefix
    
.data

    message: .asciz "Hello World!\n"

.text

.global main

main:
    xor eax, eax
    lea rdi, [rip + message]
    jmp printf

ammarfaizi2@integral:/tmp/test_asm$ gcc test.S -o test
ammarfaizi2@integral:/tmp/test_asm$ ./test
Hello World!
ammarfaizi2@integral:/tmp/test_asm$ 

---

编辑

为安全起见添加了xor eax, eax。见：glibc scanf Segmentation faults when called from a function that doesn't align RSP