为什么这个 vbscript 没有获取任何值？

Question

我正在尝试编写一个 vbscript，它从具有 class 属性的 <img> 标记的 src 属性中提取值作为此 cs-poster-big

这是我迄今为止尝试过的代码，

'Initializing object with Internet Explorer Application
set IE = WScript.CreateObject("InternetExplorer.Application", "IE_")

'setting properties of Internet Explorer to the newly create object
with IE
  .Visible = 0
  .navigate "http://www.roku.com/channels/#!details/12" 'INSERT WEBPAGE HERE
end with

'waiting for IE to load the page
'tried using IE.busy or IE.readyState <> 4 also
while IE.busy
  wScript.sleep 500
wend

wScript.sleep 500
'getting all image tags from the webpage
Set imgTags = IE.document.getElementsByTagName("IMG")

'iterating through the image tags to find the one with the class name specified
 For Each imgTag In imgTags
      'tried imgTag.className also
  If imgTag.getAttribute("class") = "cs-poster-big" Then MsgBox "src is " & imgTag.src

next

IE.quit
set IE= Nothing

MsgBox "End of script"

它没有显示任何值，但你可以查看页面的源代码here，你可以看到它有一个<img>标签和classcs-poster-big

我不明白为什么它没有显示在我的脚本中

Answer 1

Do While IE.Busy Or IE.ReadyState <> 4 
    WScript.Sleep 500
Loop

等待页面完全加载。

编辑 - 虽然这在 IE10 中有效，但 IE8 无法找到图像。其他版本未测试。

在这种情况下，请尝试将您的网址更改为

http://www.roku.com/channels?_escaped_fragment_=details/12/netflix#!details/12/netflix

避免动态生成内容的问题。

此外，在 IE8 中，需要更改代码以获取图像的类名。应该是

Do While IE.Busy Or IE.ReadyState <> 4 
    WScript.Sleep 100
Loop

Set imgTags = IE.document.getElementsByTagName("IMG")

 For Each imgTag In imgTags
    imgClass = imgtag.getAttribute("class")
    If IsNull( imgClass ) Then 
        imgClass = imgTag.className
    End If
    If imgclass = "cs-poster-big" Then 
        MsgBox "src is " & imgTag.src
    End If
Next

但不是解决方案，只是一种解决方法。