德摩根在 Haskell 中的定律通过 Curry-Howard 通信

Question

我在 Haskell 中实现了四个德摩根定律中的三个：

notAandNotB :: (a -> c, b -> c) -> Either a b -> c
notAandNotB (f, g) (Left x)  = f x
notAandNotB (f, g) (Right y) = g y

notAorB :: (Either a b -> c) -> (a -> c, b -> c)
notAorB f = (f . Left, f . Right)

notAorNotB :: Either (a -> c) (b -> c) -> (a, b) -> c
notAorNotB (Left f)  (x, y) = f x
notAorNotB (Right g) (x, y) = g y

但是，我不认为有可能实施最后一条法律（有两个居民）：

notAandBLeft  :: ((a, b) -> c) -> Either (a -> c) (b -> c)
notAandBLeft  f = Left  (\a -> f (a, ?))

notAandBRight :: ((a, b) -> c) -> Either (a -> c) (b -> c)
notAandBRight f = Right (\b -> f (?, b))

在我看来，有两种可能的解决方案：

1. 使用undefined 代替?。这不是一个好的解决方案，因为它是作弊。

2. 使用单态类型或有界多态类型来编码默认值。

   notAandBLeft  :: Monoid b => ((a, b) -> c) -> Either (a -> c) (b -> c)
   notAandBLeft  f = Left  (\a -> f (a, mempty))
   
   notAandBRight :: Monoid a => ((a, b) -> c) -> Either (a -> c) (b -> c)
   notAandBRight f = Right (\b -> f (mempty, b))
   

   这不是一个好的解决方案，因为它比德摩根定律更弱。

我们知道德摩根定律是正确的，但我认为最后一条定律不能用 Haskell 编码是否正确？这对 Curry-Howard 同构有什么看法？如果不能将每个证明都转换为等效的计算机程序，这并不是真正的同构，对吧？

Answer 1

第四定律是not intuitionistic。你需要排中公理：

lem :: Either a (a -> c)

或皮尔斯定律：

pierce :: ((a -> c) -> c) -> a

证明它。

Answer 2

让我印象深刻的一件事是，您似乎没有在任何地方使用否定的定义或任何属性。

阅读Haskell Wikibooks article on the CHI 后，这里有一个假设你有一个排中定律作为定理的证明：

exc_middle :: Either a (a -> Void)

notAandB de Morgan 定律的证明如下：

notAandB' :: Either a (a -> Void) -> ((a,b) -> Void) -> Either (a -> Void) (b -> Void)
notAandB' (Right notA) _ = Left notA
notAandB' (Left a)     f = Right (\b -> f (a,b))

notAandB = notAandB' exc_middle