Alternative的“一些”和“许多”有什么用？

Question

Alternative，Applicative的扩展，声明empty，<|>和这两个函数：

一个或多个：

some :: f a -> f [a]

零个或多个：

many :: f a -> f [a]

如果定义，some 和 many 应该是方程的最小解：

some v = (:) <$> v <*> many v

many v = some v <|> pure []

我找不到定义了some 和many 的实例。 它们的含义和实际用途是什么？它们是否被使用过？仅仅从这个定义我无法理解他们的目的。

更新：我不是在问Alternative 是什么，而是some 和many 是什么

Answer 1

在 STM Applicative 中，some 的意思是：继续尝试直到成功至少一次，然后继续尝试直到失败。 many 的意思是：尽可能多地这样做，直到失败。

Answer 2

TL;DR: some 是一个或多个，many 是通过熟悉的 maximal munch 规则一遍又一遍地执行相同计算而收集的 0 个或多个结果。为了使这一点有意义，必须进行一些状态传递（和更改）以某种方式减少可能性域，否则它将无限重复。并且状态传递和解析密切相关。

---

一个基本的例子：with

import Control.Monad(Functor(..))
import Control.Applicative
import Data.Char

-- char string parser
newtype P a = P { runP :: String -> [(a,String)] }

-- runP (P p) s = p s

instance Functor P where
  -- fmap :: (a -> b) -> f a -> f b
  fmap f (P q) = P (\s -> [ (f y,ys) | (y,ys) <- q s])

instance Applicative P where
  -- pure :: a -> f a
  pure x = P (\s -> [(x,s)])
  -- (<*>) :: f (a -> b) -> f a -> f b
  P p <*> P q = P (\s -> [(x y, ys) | (x,xs) <- p s, (y,ys) <- q xs])

letter = P p where      -- sample parser
  p (x:xs) | isAlpha x = [(x,xs)]
  p _ = []

我们有

*Main Data.Char> runP letter "123"
[]
*Main Data.Char> runP letter "a123"
[('a',"123")]
*Main Data.Char> runP ( (:) <$> letter <*> pure []) "a123"
[("a","123")]
*Main Data.Char> runP ( (:) <$> letter <*> ((:)<$>letter <*> pure []) ) "a123"
[]
*Main Data.Char> runP ( (:) <$> letter <*> ((:)<$>letter <*> pure []) ) "ab123"
[("ab","123")]   -- NOT NICE ^^^^^^^^^^^^^^^^^^^^ -}

然后，用

instance Alternative P where
  -- (<|>) :: f a -> f a -> f a
  P p <|> P q = P (\s-> p s ++ q s)
  -- empty :: f a   -- the identity of <|>
  empty = P (\s-> [])

我们得到

*Main Data.Char> runP (many letter) "ab123"
[("ab","123"),("a","b123"),("","ab123")]
*Main Data.Char> runP (some letter) "ab123"
[("ab","123"),("a","b123")]

*Main Data.Char> runP (optional letter) "ab123"
[(Just 'a',"b123"),(Nothing,"ab123")]
*Main Data.Char> runP (optional letter) "123"
[(Nothing,"123")]

Prelude Main Data.Traversable> runP (sequenceA $ replicate 2 letter) "ab123"
[("ab","123")]               --  NICE  ^^^^^^^^^^^^^^^^^^^
-}

Answer 3

我倾向于在 Applicative 解析器组合库中看到它们。

a :: Parser [String]
a = some (string "hello")

我看到many 在parsers 中的default definitions of Parsing 中用于目的。

我认为 Parsec 作为解析器组合库的主要示例隐藏了 some/many 的使用，因为它重新定义了 (<|>) 之类的东西。

Answer 4

regex-applicative 包为RE（正则表达式）类型定义了a custom many method。正则表达式以及 RE 解析器的大小必须是有限的，因此对 some 和 many 使用默认定义会导致无限循环！幸运的是，many 只是经典的正则表达式*。

该包还包含some 的定义，但它看起来太像默认定义，没有什么有趣的。

Answer 5

Will 提供了一个很好的例子来激励使用这些方法，但您似乎对类型类仍有误解。

类型类定义列出了存在于类型类的所有实例的方法的类型签名。它还可能提供这些方法的默认实现，这就是 Alternative 的 some 和 ma​​ny 方法所发生的情况。

为了成为有效的实例，必须为实例定义所有方法。因此，您发现没有专门为 some 或 ma​​ny 定义实例的那些使用 default 实现，并且它们的代码与您的问题中列出的完全相同。

所以，为了清楚起见，确实定义了 some 和 ma​​ny 并且可以与所有 Alternative 实例一起使用，这要归功于默认定义与类型类定义一起给出。