如何在 vb.net 中将一个类附加到另一个相同的类

Question

PropertyPolicy 是一个定义多个字段/实体的集合的类。有时需要两个单独的函数来构建集合。 （LoadEstateAIN 和 LoadAIN）。我需要结合两个类的结果，但尝试过 concat 但得到一个强制转换异常。这里有什么用？

Public Class PropertyPolicy

    Private agentfield As Entity
    Private aininsuredfield() As Entity
    Private billinginfofield As BillingInfo
    Private cancellationdatefield As Date
    Private claimsfield() As Claims


    Public Property Agent As Entity
        Get
            Return Me.agentfield
        End Get
        Set(ByVal value As Entity)
            Me.agentfield = value
        End Set
    End Property

    Public Property AINInsured() As Entity()
        Get
            Return Me.aininsuredfield
        End Get
        Set(ByVal value As Entity())
            Me.aininsuredfield = value
        End Set
    End Property

    Public Property BillingInfo As BillingInfo
        Get
            Return Me.billinginfofield
        End Get
        Set(ByVal value As BillingInfo)
            Me.billinginfofield = value
        End Set
    End Property

    Public Property CancellationDate As Date
        Get
            Return Me.cancellationdatefield
        End Get
        Set(ByVal value As Date)
            Me.cancellationdatefield = value
        End Set
    End Property

    Public Property Claims() As Claims()
        Get
            Return Me.claimsfield
        End Get
        Set(ByVal value As Claims())
            Me.claimsfield = value
        End Set
    End Property

End Class



Dim propTemp1 As New PropertyPolicy
Dim propTemp2 As New PropertyPolicy
Dim propTempComb As New PropertyPolicy

propTemp1.AINInsured = LoadEstateAIN(policyid, asofDate, lob, NINclientid, estatecompany)
propTemp2.AINInsured = LoadAIN(policyid, asofDate, lob, NINclientid, estatecompany)

propTempComb.AINInsured = propTemp1.AINInsured.Concat(propTemp2.AINInsured)

Answer 1

Concat 的结果不是数组；这是一个IEnumerable(Of T)。在您的情况下，它是IEnumerable(Of Entity)。如果要将其分配回数组，只需将 ToArray() 添加到 Concat 的末尾即可。

propTempComb.AINInsured = propTemp1.AINInsured.Concat(propTemp2.AINInsured).ToArray()

分解这行代码：

[instance3].[property] = [instance1].[property].Concat([instance2].[property])

将Concat的结果赋值给属性，但是属性是一个数组，所以你需要将一个IEnumerable(Of Entity)的Concat的结果改成一个ToArray微不足道的数组。

我可以更进一步，建议您不要将数组用作公共成员，而应使用 IEnumerable。此外，对于其中一些公共/公共属性，自动属性将是更好的选择。

Public Class PropertyPolicy

    Private aininsuredfield As Entity()
    Private claimsfield As Claims()

    Public Property Agent As Entity
    Public Property BillingInfo As BillingInfo
    Public Property CancellationDate As Date

    Public Property AINInsured() As IEnumerable(Of Entity)
        Get
            Return aininsuredfield
        End Get
        Set(value As IEnumerable(Of Entity))
            aininsuredfield = value.ToArray()
        End Set
    End Property

    Public Property Claims() As IEnumerable(Of Claims)
        Get
            Return claimsfield
        End Get
        Set(value As IEnumerable(Of Claims))
            claimsfield = value.ToArray()
        End Set
    End Property

End Class

顺便说一句，这将导致您的原始代码在没有 ToArray() 的情况下工作

propTempComb.AINInsured = propTemp1.AINInsured.Concat(propTemp2.AINInsured)