如何创建 Applescript 来执行终端命令和密码

Question

我四处寻找，但找不到适合我的问题的东西。

我想创建一个脚本来复制以下内容：

1. 打开终端

2. 执行以下命令：

   sudo kextunload /System/Library/Extensions/AppleHDA.kext
   

3. 然后让它为我输入我的 OSX 管理员密码。

4. 然后执行以下：

   sudo kextload /System/Library/Extensions/AppleHDA.kext
   

我对applescript完全陌生，所以希望有人可以帮助我。

谢谢！

Answer 1

对该问题的评论中的提示是正确的（在 [Apple] 脚本编辑器中，选择 File > Open Dictionary...，选择 StandardAdditions.osax，然后搜索 do shell script 以查看完整的语法），但重要的是要注意do shell script 不会打开终端窗口；相反，它会运行隐藏的 shell 命令并返回其结果 - 这通常是更可取的：

• do shell script 的返回值是 shell 命令的 stdout 输出。
• 如果 shell 命令返回非零退出代码，AppleScript 将抛出错误，错误消息将包含命令的 stderr 输出。

要以管理权限运行命令，您有 2 个选项：

• [推荐]让AppleScript显示密码提示：

set shCmds to "kextunload /System/Library/Extensions/AppleHDA.kext;
kextload /System/Library/Extensions/AppleHDA.kext"

# This will prompt for an admin password, then execute the commands
# as if they had been run with `sudo`.
do shell script shCmds with administrator privileges  

• [不推荐出于安全原因]将密码作为参数传递：

set shCmds to "kextunload /System/Library/Extensions/AppleHDA.kext;
kextload /System/Library/Extensions/AppleHDA.kext"

# Replace `{myPassword}` with your actual password.
# The commands will run as if they had been executed with `sudo`.
do shell script shCmds ¬
   user name short user name of (system info) password "{myPassword}" ¬
   with administrator privileges 

如前所述，如果出现问题 - 无论是由于密码无效或取消密码对话框，还是 shell 命令返回非零退出代码 - 都会引发运行时错误。 这是一个捕获它并通过display alert报告它的示例。

try
    do shell script shCmds with administrator privileges
on error errMsg number errNo
    display alert "Executing '" & shCmds & "' failed with error code " & ¬
        errNo & " and the following message: " & errMsg
    return
end try