使用 AWK 比较多个文件中的字段时的条件匹配

Question

我想了解在 AIX 6.x 平台上比较 AWK 中不同文件的多个字段时如何/是否可以包含某些条件。以下是我正在尝试做的事情：

Employee.txt (last column is the **status**)
1|canoeing|Sam|Smith|Seatle|X
2|jogging|Barry|Jones|Seatle|
3|football|Garry|Brown|Houston|
4|jogging|George|Bla|LA|X
5|basketballCeline|Wood|Atlanta|
6|tennis|Jody|Ford|Chicago|

Car.txt (last column is **availability**)
100|football|red|1|Y
110|tennis|green|9|N
120|hockey|yellow|2|N
130|football|yellow|6|N
140|jogging|red|8|Y
150|canoeing|white|0|
    
awk -F"|" '
NR == FNR {
   empcar[$3]
   next
}
{
   print > ($1 in empcar ? "match.txt" : "no_match.txt")
}' Car.txt Employee.txt

我喜欢在打印匹配的记录之前检查员工状态是否为 Active（没有 X）和汽车可用性 (Y) 是否相同。这可行吗？

非常感谢， 乔治

Answer 1

您可以通过以下方式检查两个文件中的其他条件：

awk -F"|" '
NR==FNR {
   if ($NF == "Y")
      empcar[$(NF-1)]
   next
}
{
   print > ($NF != "X" && $1 in empcar ? "match.txt" : "no_match.txt")
}' Car.txt Employee.txt

Answer 2

使用您展示的示例，请尝试关注awk 代码。

awk '
BEGIN{ FS=OFS="|" }
FNR==NR{
  arr[$1]=$NF
  arr1[$1]=$0
  next
}
arr[$3]!="X" && $NF=="Y"{
  print arr1[$3] > ("match.txt")
  arr2[$3]
}
END{
  for(i in arr1){
    if(!(i in arr2)){
      print arr1[i] > ("no_match.txt")
    }
  }
}
' Employee.txt car.txt

说明：为上述代码添加详细说明。

awk '                                      ##Starting awk program from here.
BEGIN{ FS=OFS="|" }                        ##Setting FS and OFS to | in BEGIN section.
FNR==NR{                                   ##Checking condition FNR==NR which will be TRUE when Employee.txt is being read.
  arr[$1]=$NF                              ##Creating array arr with index of $1 and value of last field.
  arr1[$1]=$0                              ##Creating array arr1 with index of $1 and value of current line.
  next                                     ##next will skip all further statements from here.
}
arr[$3]!="X" && $NF=="Y"{                  ##Checking condition if arr array with index of 3rd column value is not X and last field is Y then do following.
  print arr1[$3] > ("match.txt")           ##Printing respective entry from Employee.txt into match.txt file here.
  arr2[$3]                                 ##Creating an entry in arr2 with index of $3 here.
}
END{                                       ##Starting END block of this awk program from here.
  for(i in arr1){                          ##Traversing through arr1 here.
    if(!(i in arr2)){                      ##Checking if i(current item index) is NOT present in arr2 then do following.
      print arr1[i] > ("no_match.txt")     ##Printing respective value to no_match.txt file.
    }
  }
}
' Employee.txt car.txt                     ##Mentioning Input_file names here.

Answer 3

这个怎么样：

awk -F'|' 'FNR==NR { empcar[$3]; next } $1 in empcar && $5 != "X"' cars emps

输出：

2|Barry|Jones|Seatle|
6|Jody|Ford|Chicago|