使用 vbscript 编辑 excel 文件，但编辑需要很长时间才能完成

Question

/* 我使用 vb 脚本编辑 excel 文件的原因是：excel 文件会一直不同但格式相同，用户不想在他们的工作簿上保存 VBA 宏。

我从第 3 列获取值并将这些值添加到第 9 列的末尾。

*/

Set xlApp=CreateObject("Excel.Application")
Set xlBook=xlApp.Workbooks.Open("filepath", 0, true)
xlApp.visible=true


Set xlSheet=xlBook.Worksheets("Proposal Spreadsheet")
row=xlSheet.UsedRange.Rows.Count
col=xlSheet.UsedRange.Columns.Count

dim i 

For i=15 to xlSheet.UsedRange.Rows.Count 
cell=xlSheet.Cells(i,3).Value
celli=xlSheet.Cells(i,9).Value+"("+cell+")" //I am combining column 3 with column 9

xlSheet.Cells(i,9).Value=celli


Next

xlBook.Save
xlApp.Run "Submit_To_iDesk"
xlBook.Close

xlApp.Quit
Set xlApp=Nothing 
Set xlBook=Nothing 
WScript.Quit

Answer 1

如果UsedRange 没有返回有用的数字，请使用一种更可靠的方法来查找列中最后使用的单元格：

Set xlApp=CreateObject("Excel.Application")
Set xlBook=xlApp.Workbooks.Open("filepath", 0, true)
xlApp.visible=true

Set xlSheet=xlBook.Worksheets("Proposal Spreadsheet")
row=xlSheet.Cells(xlSheet.Rows.Count, 9).End(-4162).Row ' -4162 is equivalent of "xlUp"

dim i 

For i=15 to row
    cell=xlSheet.Cells(i,3).Value
    celli=xlSheet.Cells(i,9).Value

    xlSheet.Cells(i,9).Value=celli & "(" & cell & ")"
Next

xlBook.Save
xlApp.Run "Submit_To_iDesk"
xlBook.Close

xlApp.Quit
Set xlApp=Nothing 
Set xlBook=Nothing 
WScript.Quit

Answer 2

加快过程的关键是减少写操作的次数。
这是我的做法

• 将范围变量（target）设置为第 9 列中的目标单元格
• 从目标范围创建一个值数组
• 编辑 values 数组的元素 将 values 数组写回原来的数组
• 1 次操作中的目标范围

---

Set xlApp = CreateObject("Excel.Application")
Set xlBook = xlApp.Workbooks.Open("C:\Users\best buy\Desktop\Book1.xlsx", 0, True)

xlApp.Visible = True
xlApp.ScreenUpdating = False
Set xlSheet = xlBook.Worksheets("Proposal Spreadsheet")

Dim i, values, LastRow, target

With xlSheet
    LastRow = xlSheet.UsedRange.Rows.Count
    Set target = .Range(.Cells(15, 9), .Cells(LastRow, 9))
    values = target.Value

    For i = LBound(values, 1) To UBound(values, 1)
        values(i, 1) = values(i, 1) & "(" & .Cells(i + 15 - LBound(values, 1), 3) & ")"
    Next
    target.Value = values
End With

xlBook.Save
'xlApp.Run "Submit_To_iDesk"
xlBook.Close
xlApp.ScreenUpdating = True
xlApp.Quit
Set xlApp = Nothing
Set xlBook = Nothing
WScript.Quit