VBA中的变量样式

Question

所以我有这个代码，它将文本中的每个 X 替换为“Asunto (1,2,..): Expediente N°”。我尝试设置这部分代码的样式： 我想要的是在 Arial 11 Bold 中替换 X 的文本

.Text = "Asunto" & " " & i & " " & "Expediente N°"

我试过了，但样式适用于整个文档，而不仅仅是那个文本，我不知道还能尝试什么

     Sub Macro1()
'
' Macro1 Macro
'
'
Application.ScreenUpdating = False
Dim i As Long
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "X"
    .Replacement.Text = ""
    .Format = False
    .Forward = True
    .Wrap = wdFindStop
    .MatchWildcards = True
    .Execute
  End With
  Do While .Find.Found
    i = i + 1
    .Text = "Asunto" & " " & i & " " & "Expediente N°"
    .Find.Execute
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
  With .Font
  .Bold = True
  .Name = "Arial"
  .Size = 11
End With
Application.ScreenUpdating = True
MsgBox i & " Coincidencias."
End With
End Sub

Answer 1

您没有应用样式 - 您所做的只是用硬格式覆盖已经存在的任何样式。做一个样式，例如：

Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "X"
    .Replacement.Text = ""
    .Format = False
    .Forward = True
    .Wrap = wdFindStop
    .MatchWildcards = True
  End With
  Do While .Find.Execute
    i = i + 1
    .Text = "Asunto" & " " & i & " " & "Expediente N°"
    .Style = wdStyleStrong
    .Collapse wdCollapseEnd
  Loop
End With
Application.ScreenUpdating = True
MsgBox i & " instances found."
End Sub

在上面，我通过常量 wdStyleStrong 使用了 Word 的“强”样式。如果您的文本已经是 11pt Arial，这就是您所需要的。否则，您应该定义一个合适的 11pt Arial Bold 字符样式并应用它。