变量的 VBA 日期格式

Question

我需要将电子表格列中的内容从文本转换为日期。

单元格格式为文本，并指示输入者输入日期为“ddmmyyyy”。

发生了意外，我发现了一些无法解析为日期的内容，包括“未知”之类的条目。

所以我使用了一个声明为日期的变量，并编写了一个错误处理程序来处理无法解析的内容。

现在我无法锻炼。

如果日期是 2000 年 3 月 3 日，并且有人将其输入为“03332000”，则不会解析，因为“33”不能是一个月或一天；它被我想要的错误处理程序捕获。

但如果输入为“03132000”，我想不出办法阻止 VBA 将其转换为有效日期为“13/03/2000”。

声明日期变量的格式不会阻止 VBA 解析日期。

我可以编写一些东西来测试字符串的日期和月份部分的数字范围，但那是额外的代码行，我希望只通过错误处理程序来完成。

Answer 1

我会采取一些不同的方法，让 Excel 来完成这项工作。

Public Function ValidateDate(ByVal strDate As String) As Boolean
    Dim intDay As Integer, intMonth As Integer, intYear As Integer, dtDate As Date

    ValidateDate = True

    On Error GoTo IsInValid

    If Len(strDate) <> 8 Then GoTo IsInValid
    If Not IsNumeric(strDate) Then GoTo IsInValid

    intDay = Left(strDate, 2)
    intMonth = Mid(strDate, 3, 2)
    intYear = Right(strDate, 4)

    dtDate = DateSerial(intYear, intMonth, intDay)

    If DatePart("d", dtDate) <> intDay Then GoTo IsInValid
    If DatePart("m", dtDate) <> intMonth Then GoTo IsInValid
    If DatePart("yyyy", dtDate) <> intYear Then GoTo IsInValid

    Exit Function

IsInValid:
    ValidateDate = False

End Function

...这将确保与闰年等相关的任何内容仍能正常工作，并将确保所有条目都得到正确验证。

Answer 2

如果你放置：

03332000

在单元格 A1 中并运行：

Sub CheckDate()
    Dim s As String, d As Date
    s = Range("A1").Text
    d = DateSerial(CInt(Right(s, 4)), CInt(Mid(s, 3, 2)), CInt(Left(s, 2)))
    MsgBox s & vbCrLf & d
End Sub

你会得到：

因此，即使有效月份只能在 [1-12] 范围内，Excel 仍试图通过将 33 解释为未来日期的预测来“帮助”您。例如，如果月份输入为 13，Excel 会将其视为下一年的12 月！

您不能为此依赖错误处理。您需要以下检查：

Sub CheckDate2()
    Dim s As String, d As Date
    Dim dd As Integer, mm As Integer, yr As Integer

    s = Range("A1").Text

    yr = CInt(Right(s, 4))
    mm = CInt(Mid(s, 3, 2))
    dd = CInt(Left(s, 2))

    If yr = 0 Or yr < 1900 Then
        MsgBox "year is bad"
        Exit Sub
    End If

    If dd = o Or dd > 31 Then
        MsgBox "day is bad"
        Exit Sub
    End If

    If mm = 0 Or mm > 12 Then
        MsgBox "month is bad"
        Exit Sub
    End If

    d = DateSerial(yr, mm, dd)
    MsgBox s & vbCrLf & d
End Sub

您还可以进行其他检查，例如查看字段的长度等。