按字母顺序对模块子例程进行排序

Question

我想按字母顺序对我的模块子例程进行排序（我有很多子例程，如果子例程在文件中排序，我认为编辑文件会更容易）。例如给定A.pm:

package A;
use warnings;
use strict;

sub subA {
  print "A\n";
}

sub subC {
  print "C\n";
}
sub subB {
  print "B\n";
}

1;

我想运行一个sortSub A.pm 给：

package A;
use warnings;
use strict;

sub subA {
  print "A\n";
}
sub subB {
  print "B\n";
}
sub subC {
  print "C\n";
}
1;

是否有任何 CPAN 资源可以帮助完成这项任务？

Answer 1

要解析和重新格式化 Perl 代码，您应该使用PPI。

这是 Perl::Critic 和 Perl::Tidy 用来完成所有壮举的工具。

在这种情况下，我研究了PPI::Dumper 的代码，以了解如何导航PPI 返回的文档树。

下面将解析源代码并分离出包含子例程和 cmets 的部分。它会将子程序之前的 cmets、pod 和空格与它联系起来，然后它会按名称对所有相邻的 subs 进行排序。

use strict;
use warnings;

use PPI;
use Data::Dump;

my $src = do { local $/; <DATA> };

# Load a document
my $doc = PPI::Document->new( \$src );

# Save Sub locations for later sorting
my @group = ();
my @subs  = ();

for my $i ( 0 .. $#{ $doc->{children} } ) {
    my $child = $doc->{children}[$i];

    my ( $subtype, $subname )
        = $child->isa('PPI::Statement::Sub')
        ? grep { $_->isa('PPI::Token::Word') } @{ $child->{children} }
        : ( '', '' );

    # Look for grouped subs, whitespace and comments.  Sort each group separately.
    my $is_related = ($subtype eq 'sub') || grep { $child->isa("PPI::Token::$_") } qw(Whitespace Comment Pod);

    # State change or end of stream
    if ( my $range = $is_related .. ( !$is_related || ( $i == $#{ $doc->{children} } ) ) ) {
        if ($is_related) {
            push @group, $child;

            if ( $subtype ) {
                push @subs, { name => "$subname", children => [@group] };
                @group = ();
            }
        }

        if ( $range =~ /E/ ) {
            @group = ();

            if (@subs) {
                # Sort and Flatten
                my @sorted = map { @{ $_->{children} } } sort { $a->{name} cmp $b->{name} } @subs;

                # Assign back to document, and then reset group
                my $min_index = $i - $range + 1;
                @{ $doc->{children} }[ $min_index .. $min_index + $#sorted ] = @sorted;

                @subs = ();
            }
        }
    }
}

print $doc->serialize;

1;

__DATA__
package A;
use warnings;
use strict;

=comment
Pod describing subC
=cut
sub subC {
    print "C\n";
}

INIT {
    print "Hello World";
}

sub subB {
    print "B\n";
}

# Hello subA comment
sub subA {
    print "A\n";
}

1;

输出：

package A;
use warnings;
use strict;

=comment
Pod describing subC
=cut
sub subC {
    print "C\n";
}

INIT {
    print "Hello World";
}

# Hello subA comment
sub subA {
    print "A\n";
}

sub subB {
    print "B\n";
}

1;

Answer 2

首先，这是我的解决方案；

#!/bin/sh
TOKEN=sub

gsed -e ':a;N;$!ba;s/\n/__newline__/g' "$1" > "$1.out"
gsed -i "s/__newline__\\s*$TOKEN\W/\\nsub /g" "$1.out"
sort $1.out -o $1.out
gsed -i 's/__newline__/\n/g' $1.out

用法：token_sort.sh myfile.pl

这就是它的工作原理；

• 用占位符替换所有换行符，__newline__
• 将所有$TOKENS（在这种情况下为潜艇）拆分到他们自己的行中
• 使用 unix sort 对行进行排序
• 全部换行
• 您现在应该在 myfile.pl.out 中拥有文件的排序副本

一些注意事项；

• 在文件顶部添加注释“#Something”或“#!/usr/bin/env perl”；这将确保标题块保持在顶部排序。
• 已排序的块将是当前子节点到下一个子节点的开始 - 子节点上方的 cmets 将与前一个子节点一起排序。
• 您需要使用 gnu-sed 才能工作，在 Mac 上这意味着执行“brew install gnu-sed”