vim 中的字符循环

Question

我想创建一个 vim 宏来做下一步：

如果我输入字符“a”、“e”、“o”、“i”或“u”并按下快捷键 p.e。 F12 每次点击快捷键都要循环遍历字符

p.e.

a -> F12 -> à -> F12 -> â -> F12 -> ä -> F12 -> ä -> F12 -> 再次回到“a”
A -> F12 -> À -> F12 -> Â -> F12 -> Ä -> F12 -> Ä -> F12 -> 再次回到“A”

同样
e --> eéèêëée
E --> EÉÊÈËÉE
i --> iîïi
我 --> 我是我
o --> oôöo
O --> OÔÖO
你 --> uûùüüu
U --> UÛÙÜU

谁能帮帮我？

Answer 1

这是一个功能，可以满足您的需求。它的工作原理是抓取光标下的 unicode 字符，查看它是否存在于某个字符列表中，如果存在，则将其推进到该列表中的下一个字符。我通过复制它，从寄存器中提取它，然后在函数结束时恢复寄存器的原始内容，以一种丑陋的方式抓住光标下的字符。一定有更优雅的方式！

function! CycleThroughChars()
    let x_contents = getreg("x")
    let x_type = getregtype("x")
    let lists = [ ["a","à","â","ä","a"],
                \ ["A","À","Â","Ä","A"],
                \ ["e","é","è","ê","ë","e"],
                \ ["E","É","Ê","È","Ë","E"],
                \ ["i","î","ï","i"],
                \ ["I","Î","Ï","I"],
                \ ["o","ô","ö","o"],
                \ ["O","Ô","Ö","O"],
                \ ["u","û","ù","ü","u"],
                \ ["U","Û","Ù","Ü","U"] ]
    sil exe 'normal! "xyl'
    let c_char = @x
    for this_list in lists
        let c_index = index(this_list,c_char)
        if c_index != -1
            sil exe "normal! r" . this_list[c_index+1]
            break
        endif
    endfor
    call setreg("x",x_contents,x_type)
    startinsert
endfunction
inoremap <silent> <F12> <ESC>:call CycleThroughChars()<CR><right>

希望这会有所帮助。

编辑

我意识到第二个 for 循环是多余的，所以我将它从函数中删除。功能不受影响，但每个列表只需调用一次index()。

Answer 2

编辑：我能够通过调用 matchstr() 来替换补充函数。现在比以前干净了一点。

为了完整起见，这是我想出的。

let g:unicode_list = [
\    [ 'a', 'à', 'â', 'ä' ],
\    [ 'A', 'À', 'Â', 'Ä' ],
\    [ 'e', 'é', 'è', 'ê', 'ë' ],
\    [ 'E', 'É', 'Ê', 'È', 'Ë' ],
\    [ 'i', 'î' ], 
\    [ 'I', 'Î', 'Ï' ],
\    [ 'o', 'ô', 'ö' ],
\    [ 'O', 'Ô', 'Ö' ],
\    [ 'u', 'û', 'ù', 'ü' ],
\    [ 'U', 'Û', 'Ù', 'Ü' ],
\]

function! CycleUnicode(mode)
    let char = matchstr(getline('.'), '.', col('.')-1)
    for sublist in g:unicode_list
        let idx = index(sublist, char)
        if idx >= 0
            try
                let char = sublist[idx+1]
            catch /E684/
                let char = sublist[0]
            endtry
            execute "normal! r" . char
            break 
        endif
    endfor
    if a:mode == 'i'
        startinsert
    endif
endfunction

inoremap <f12> <esc>:call CycleUnicode('i')<enter><right>
nnoremap <f12> :call CycleUnicode('n')<enter>