嵌套函数调用范围和语法

Question

我正在尝试调用嵌套递归 perl 函数，但我无法使用正确的语法。

问题：对嵌套函数执行递归调用的正确语法是什么（如果嵌套函数应该被递归调用）？

答案：参考已接受答案中建议的伪代码。

这是一个伪代码sn-p：

use Scalar::Util;
sub outerfunction {
  my $innerfunction = sub {
    # Do something
    innerfunction(); 
    # Do other things
  }; 
  Scalar::Util::weaken($innerfunction); 
  &$innerfunction(@_);
}; 

我尝试按以下方式调用内部函数（带有相应的错误消息）：

innerfunction

未定义的子程序 &main::innerfunction

&innerfunction

未定义的子程序 &main::innerfunction

&$innerfunction

全局符号“$innerfunction”需要明确的包名

我也尝试将内部函数声明为本地函数，但收到以下内容：

全局符号“$innerfunction”需要明确的包名

我在解释语言方面没有太多经验，因此任何与内存/堆栈泄漏/损坏或上述伪代码的其他危险（递归系统限制除外）相关的附带评论也将不胜感激。

谢谢！ 在 Linux 2.6.34.7-61.fc13.x86_64 上运行的 perl v5.10.1

Answer 1

innerfunction() 语法仅适用于已安装到符号表中的子例程（例如 sub NAME {...} 语法）。您需要将您的内部函数称为$innerfunction->() 或&$innerfunction()，但您遇到的问题是$innerfunction 词法的范围。

当您使用my 声明变量时，该变量在该语句结束后 的范围内。所以你需要拆分你的声明：

 my $innerfunction;
    $innerfunction = sub {
        ...
        $innerfunction->();
        ...
    };

要使用weaken 打破循环引用，通常的模式是：

use Scalar::Util;
sub outer_function {
    my $weak_ref;
    $weak_ref = my $strong_ref = sub {
        # Do something
        $weak_ref->(); 
        # Do other things
    };
    Scalar::Util::weaken($weak_ref); 
    return $strong_ref;
};

所以现在，一旦$strong_ref 超出范围，子例程就会被垃圾回收。

Answer 2

sub outer_function {
    local *inner_function = sub {
        # Do something
        inner_function(); 
        # Do other things
    };
    inner_function();
};

几乎与以下内容一样好，但更清晰：

use Scalar::Util qw( weaken );
sub outer_function {
    my $weak_ref;
    my $strong_ref = sub {
        # Do something
        $weak_ref->(); 
        # Do other things
    };
    weaken($weak_ref = $strong_ref);  # Avoid memory leak.
    $strong_ref->();
};