重构使用 Reader monad 的 Haskell 函数

Question

我有一些看起来像这样的代码，忽略所有与我的问题无关的代码：

import qualified Control.Monad.Reader as Reader

data FooEnv = FooEnv { bar :: Int -> Int }
type FooReader = Reader.Reader FooEnv

foo :: Int -> FooReader String
foo i = Reader.liftM show $ bar' i
  where
    bar' i' = do
      bar'' <- Reader.asks bar
      return $ bar'' i'

有没有办法重构这个？具体来说，嵌套的bar' 函数最困扰我。可以压缩成一行吗？

Answer 1

我们可以做一些等式推理。首先让我们看看bar'。我就这样写吧

asks bar >>= \z -> return (z i)

事实证明，liftM 被定义为符合上述模式的liftM f m = m >>= \a -> return (f a)。所以我们把它替换为

liftM ($ i) (asks bar)

那么我们有foo作为存在

liftM show (liftM ($ i) (asks bar))

或者，写的有点特别

liftM show . liftM ($ i) $ asks bar

如果我们知道liftM 是fmap，我们可能会认识到Functor 法则在这里起作用

fmap show . fmap ($ i) $ asks bar -- equals
fmap (show . ($ i)) $ asks bar

我个人不太喜欢将 ($ i) 用作函数，所以让我们将其重写为显式 lambda

fmap (\f -> show (f i)) (asks bar)

现在，我们可以决定通过在调用站点使用bar 来消除asks（即使用bar 作为bar :: FooEnv -> Int -> Int 类型的函数

fmap (\f -> show (bar f i)) ask

作为最后一个技巧，我们可以使用 flip 在 fmapped 函数中变得毫无意义，甚至返回 asks 的使用（感谢 Ørjan Johansen）

fmap (show . flip bar i) ask  -- or even
show . flip bar i <$> ask     -- or even
asks (show . flip bar i)

我并不是说这是执行此任务的最易读或最美妙的方式，但您可以看到我们如何使用等式推理来减少碎片。