按位值读取数字列表？ （ClojureScript 技巧）

Question

我今天想知道我是否有一个数字列表。 ClojureScript 中是否有一个函数可以按位值返回由数字组成的数字？ （我不是指list()，只是一些数字）

例如：

我有一些数字 1、2、3，我正在寻找将其转换为 123（一百二十三）的函数。

我以为我通过read-string找到了解决方案

(read-string (str 1 2 3))
;=> 123

但遗憾的是，如果我想在下面讨论的函数中使用它，它就不能很好地工作。

我有一个“函数式”映射，其中键是向量，值是数字。像这样： {[0 0] 0, [0 1] 1, ... [4 5] 45, ... [9 9] 99}

我可以在这张地图上使用get 函数的唯一方法是：

(get {[0 2] 2} [0 2])
;=> 2
; or
(get {[4 5] 45} [4 5])
;=> 45

这很糟糕，但它确实有效。为了让它看起来更好，我尝试在我使用read-string 的地方定义一个函数：（读取/指的是cljs.reader）

(defn get-oxo [x y]
  (get {[x y] (read/read-string (str x y))} [x y]))
;So i can use it like this for e.g.:
(get-oxo 4 5)
;=> 45

它还返回不在地图中的值：

(get-oxo 112 358)
;=> 112358

我想问题是这样get-oxo返回的不是配对键的值，而是由x y构造的数字...

所以问题是如何修复它以返回配对键的值，而不是从我给函数的数字构造的数字？

（如果我想生成一个具有更广泛数字范围的地图，例如不仅仅是 0-9 而是 0-99，还有另一个问题。这样get-oxo 的算法不正确。我使用讨论的函数在：ClojureScript zipmap tricks me or what?)。

Answer 1

问题是你得到了什么：

只需分解你的函数以清楚地看到它：

(defn get-oxo [x y]
  (let [new-map {[x y] (read/read-string (str x y))}]
    (println new-map)
    (get new-map [x y])))
#'user/get-oxo

user> (get-oxo 100 200)
;;=> {[100 200] 100200}
;;=> 100200

所以你在函数内部生成你的地图，并得到它的关键 你得到......一个完全有效的行为

要从 your 地图中获取某些信息，您需要将 your 地图作为get 函数的第一个参数

(defn get-oxo [input x y]
  (get input [x y]))
#'user/get-oxo

user> (def data {[0 0] 0 [0 1] 1 [0 2] 2})
#'user/data

user> (get-oxo data 0 1)
1

user> (get-oxo data 2 3)
nil

然后，如果您需要键（我的意思是映射中的对）而不是值，您可以这样修改它，使用 find 函数而不是 get：

(defn get-oxo [input x y]
  (first (find input [x y])))
#'user/get-oxo

user> (get-oxo data 0 1)
[0 1]

user> (get-oxo data 2 3)
nil

同时写入和读取字符串以获取数字看起来是多余的。您可以轻松地为此创建一个简单的函数：

(defn digits->num [digits]
  (reduce (fn [acc d] (+ (* 10 acc) d))
          0
          digits))
#'user/digits->num

user> (digits->num [0])
0

user> (digits->num [])
0

user> (digits->num [1])
1

user> (digits->num [1 2 3 4])
1234

user> (digits->num [0 0 1 0])
10

Answer 2

您可以简单地 apply str 对您的数字序列起作用：

(apply str '(1 2 3))
;; => "123"