无法从 (Num a) 或 (Floating a) 推导出 (Eq a)。但可以从 (Integral a) 推导出 (Eq a)。为什么？

Question

我正在学习一个 haskell 教程（向你学习一个很好的 haskell），我正在玩我根据书中的一个函数编写的这段代码。

reverseNum :: (Num a) => a -> a
reverseNum 123 = 321
reverseNum x = 0

ghci 告诉我它不能从 (Num a) 推导出 (Eq a)。

所以我把第一行改成这个

reverseNum :: (Integral a) => a -> a

它奏效了。这很奇怪，因为我认为要成为 Num 类型类的一部分，你也需要成为 Eq 的一部分。

我又尝试了一件事情来满足我的好奇心，并将前 2 行改成了这个

reverseNum :: (Floating a) => a -> a
reverseNum 1.0 = 0.1

它给了我同样的错误。

我知道您可以通过执行reverseNum :: (Num a, Eq a) ... 之类的操作来解决此问题，但我想知道为什么 Integral 是唯一可以推导出 Eq 的。 这是为什么呢？

附：我对haskell真的很陌生，所以...要温柔:)

Answer 1

简答

因为那是前奏中Num的定义：

class Num a where
    ...

而Integral 的定义要求类型为Real 和Enum：

class (Real a, Enum a) => Integral a where
    ...

而Real 意味着Num 和Ord...

class (Num a, Ord a) => Real a where
    ...

而Ord，自然暗示Eq：

class Eq a => Ord a where
    ...

这行意味着要实现Ord，它必须也实现Eq。或者我们可以说Ord 是Eq 的子类。总之……

总结就是Num不是Eq的子类，但Integral是Eq的子类。

长答案（为什么？）

您可以想象以无法实现Eq 的方式实现Num。

newtype Sequence = Sequence (Integer -> Integer)

instance Num Sequence where
  (Sequence x) + (Sequence y) = Sequence $ \pt -> x pt + y pt
  (Sequence x) - (Sequence y) = Sequence $ \pt -> x pt - y pt
  (Sequence x) * (Sequence y) = Sequence $ \pt -> x pt * y pt
  negate (Sequence x) = Sequence $ \pt -> -pt
  abs (Sequence x) = Sequence $ \pt -> abs pt
  signum (Sequence x) = Sequence $ \pt -> signum pt
  fromInteger = Sequence . const

-- Ignore the fact that you'd implement these methods using Applicative.

这里，Sequence 是代表所有可计算序列的类型。你不能以任何合理的方式实现Eq，因为序列是无限长的！

instance Eq Sequence where
  -- This will never return True, ever.
  (Sequence x) == (Sequence y) =
      and [x pt == y pt | pt <- [0..]] &&
      and [x pt == y pt | pt <- [-1,-2..]]

所以Num 不是Eq 的子类是有道理的，因为有有用的 类型可以实现Num 但不能实现Eq。