如何激活在不同模块中命名的工作簿

Question

我从 module1 调用 module2，我在 module2 中将工作簿命名为“x”。但后来当我在 module1 中尝试“x.Activate”时，我收到一个错误“运行时错误'424'：需要对象”

我有一个相当长的模块，我想把它分成多个模块来组织。到目前为止，我已经在这个模块中创建了一个名为“INPUTS”的模块我有一个“Sub RT_CMM_DATA_COMPILER_INPUTS()”大概在未来我将在这个模块中拥有其他 Subs“Sub RT_Some_Other_Project_INPUTS()”我在“Sub RT_CMM_DATA_COMPILER_INPUTS( )”并尝试在名为沙箱的单独模块中按名称激活该工作簿。但它显示一个错误。

'RT_Sandbox Module
Sub sandbox()

    Call RT_CMM_DATA_COMPILER_INPUTS

    wkbwatchFolders_table.Activate
    lastShtRow = LASTSHEETROW(ActiveSheet)

    MsgBox lastShtRow

End Sub


'Inputs module
Sub RT_CMM_DATA_COMPILER_INPUTS()

    watchFolders_filePath = "D:\RT_CMM_Data_File_Paths.xlsx"
    Set wkbwatchFolders_table = Workbooks.Open(Filename:=watchFolders_filePath)

End Sub

我是否会尝试组织我的代码完全错误？我应该为此使用类模块吗？还是只是我缺少一些语法？

Answer 1

您缺少的关键部分是每个模块顶部的Option Explicit。

使用该选项，代码将拒绝编译，直到所有变量都被显式声明。

没有它，watchFolders_filePath 在两个过程中都是一个未声明的变量，在读取但未赋值的范围内，它的数据类型是Variant/Empty。

Rubberduck（我管理的免费、开源 VBIDE 插件项目）可以帮助您在代码中定位和修复这些问题（以及其他问题）：

• OptionExplicit验货
• UnassignedVariableUsage验货
• UndeclaredVariable验货
• VariableNotAssigned验货
• VariableNotUsed验货

---

至于您的代码，您不需要任何全局变量。 尽可能避免使用全局变量。改用函数（和参数）：

Function RT_CMM_DATA_COMPILER_INPUTS() As Workbook
    Dim watchFolders_filePath As String
    watchFolders_filePath = "D:\RT_CMM_Data_File_Paths.xlsx"
    Set RT_CMM_DATA_COMPILER_INPUTS = Workbooks.Open(Filename:=watchFolders_filePath)
End Function

Sub sandbox()

    Dim wb As Workbook
    Set wb = RT_CMM_DATA_COMPILER_INPUTS    
    wb.Activate
    lastShtRow = LASTSHEETROW(wb.ActiveSheet)

    MsgBox lastShtRow

End Sub

Answer 2

使用Public 语句将在这里工作：

Public x As Workbook 
Public your_var As Object

你需要在你的过程之外，在模块的顶部声明这些。声明这些后，您可以在任何模块中的任何位置访问它们。

在此处阅读更多信息：Declaring Variables