为什么使用 LWP::Parallel::UserAgent 时没有设置 agent()？

Question

查看UserAgent.pm 时似乎未定义。至少，据我所知，当例程到达该部分时，它是未定义的，即使我使用$pua->agent() 明确设置它。这是一个错误吗？还有init_header()，但是我尝试$pua->request->init_header()的时候也设置失败。

#!/bin/perl

use LWP::Parallel::UserAgent;

my $ua_string =
"Mozilla/5.0 (Windows NT 6.1; WOW64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/43.0.2357.81 Safari/537.36";

my $url  = "http://www.example1.com";
my $url2 = "http://www.example2.com";

my $reqs = [
    HTTP::Request->new( 'GET', $url ),
    HTTP::Request->new( 'GET', $url2 )
];

my ( $req, $res );

my $pua = LWP::Parallel::UserAgent->new();

$pua->agent($ua_string);

foreach $req ( @$reqs ) {
    $pua->register( $req );
}

my $entries = $pua->wait();
foreach ( keys %$entries ) {
    $res = $entries->{$_}->response;
    my $r = $res;
    my @redirects;
    while ( $r ) {
        $res = $r;
        $r   = $r->previous;
        push( @redirects, $res ) if $r;
    }
}

Answer 1

抱歉，$pua->agent 已设置，但 LWP::Parallel::UserAgent 没有使用它。这是a long standing bug in LWP::Parallel::UserAgent。

LWP::Parallel::UserAgent 是 LWP::UserAgent 的子类，但它是一个表现不佳的子类。它没有使用访问器，而是抓取内部字段并假设代理将存储在$self->{agent} 中。也许曾经是，但现在已经不是了。

您的特殊问题在LWP::Parallel::UserAgent::init_request() starting at line 1506。

# Extract fields that will be used below
my ($agent, $from, $timeout, $cookie_jar,
    $use_eval, $parse_head, $max_size, $nonblock) =
  @{$self}{qw(agent from timeout cookie_jar
              use_eval parse_head max_size nonblock)};

假设用户代理存储在$self->{agent} 中。它不是。它应该做这样的事情来依次调用每个访问器。

my %fields;
my @fields = qw(agent from timeout cookie_jar parse_head max_size);
for my $field (@fields) {
    $fields{$field} = $self->$field();
}

或者直接使用访问器。这将使用 LWP 的文档化接口。

nonblock 和 use_eval 是特殊情况。这些不是 LWP::UserAgent 字段，它们是由 LWP::Parallel 添加的。 use_eval 没有访问器方法。有一个LWP::Parallel::UserAgent::nonblock()，但它只是一个二传手。我不认为这是故意的。

因为它没有为use_eval 定义访问器，所以应该添加一个。您可以修复 nonblock 以始终返回其值。

sub nonblock {
    my $self = shift;
    $self->{'nonblock'} = $_[0] if defined $_[0];
    return $self->{nonblock};
}

LWP::Parallel::UserAgent 正在积极维护中，you should send a bug report 可能还有补丁。