OCaml 中的自动机

Question

我对 OCaml 有点陌生。我想在 OCaml 中实现自动机的产品构造算法。我很困惑如何在 OCaml 中表示自动机。有人可以帮我吗？

Answer 1

有限确定性自动机的简洁表示是：

type ('state,'letter) automaton = {
  initial    : 'state ;
  final      : 'state -> bool ;
  transition : 'letter -> 'state -> 'state ;
}

例如，判断一个单词是否包含奇数个'a' 的自动机可以这样表示：

let odd = {
  initial    = `even ; 
  final      = (function `odd -> true | _ -> false) ;
  transition = (function 
    | 'a' -> (function `even -> `odd | `odd -> `even)
    |  _  -> (fun state -> state))
}

另一个例子是只接受字符串"bbb" 的自动化（是的，这些来自this online handout）：

let bbb = {
  initial = `b0 ;
  final   = (function `b3 -> true | _ -> false) ;
  transition = (function 
    | 'b' -> (function `b0 -> `b1 | `b1 -> `b2 | `b2 -> `b3 | _ -> `fail)
    |  _  -> (fun _ -> `fail))
}

自动机乘积在数学上被描述为使用状态集的笛卡尔积作为新集，以及最终函数和转移函数在该集上的自然扩展：

let product a b = {
  initial = (a.initial, b.initial) ;
  final   = (fun (x,y) -> a.final x && b.final y) ;
  transition = (fun c (x,y) -> (a.transition c x, b.transition c y)
}

这个产品自动机计算两种语言的交集。您也可以使用|| 代替&& 来实现两种语言的联合。