delphi：为密码生成随机数据

Question

我需要为加密目的生成一个 12 字节的随机数据。我的第一个想法是使用类似的东西

random(maxint) * random(maxint) * random(maxint)

但我发现这在多线程上效率不高，因为随机使用全局变量 RandSeed（实际上随机不是多线程）。随机看起来也很容易猜到：

function Random(const ARange: Integer): Integer;
var
  Temp: Integer;
begin
  Temp := RandSeed * $08088405 + 1;
  RandSeed := Temp;
  Result := (UInt64(Cardinal(ARange)) * UInt64(Cardinal(Temp))) shr 32;
end;

因此，如果您知道其中一个生成的随机数，您就可以轻松猜出下一个生成的随机数...

他们是否可以替代 random 来生成我的 12 字节随机字节？

Answer 1

我看到了三种选择。

我们发布了一个开源AES-256 based Cryptographically Secure Pseudo-Random Number Generator (CSPRNG)。它有一个经过验证的熵生成器，您可以拥有多个生成器（例如，每个线程一个）。使用AES-NI硬件加速，速度非常快。

或者，如果你想生成唯一的 ID，你可以使用类似的代码，一次生成一个 32 位随机值：

{$ifdef CPUINTEL}
/// get 32-bit value from NIST SP 800-90A compliant RDRAND Intel x86/x64 opcode
function RdRand32: cardinal;
{$ifdef CPU64}
{$ifdef FPC}nostackframe; assembler;
asm
{$else}
asm
  .noframe
{$endif FPC}
{$endif CPU64}
{$ifdef CPU32}
asm
{$endif}
  // rdrand eax: same opcodes for x86 and x64
  db $0f,$c7,$f0
  // returns in eax, ignore carry flag (eax=0 won't hurt)
end;
// https://software.intel.com/en-us/articles/intel-digital-random-number-generator-drng-software-implementation-guide
{$endif}

var
  rs1: cardinal = 2654435761;
  rs2: cardinal = 668265263;
  rs3: cardinal = 3266489917;

function Random32: cardinal;
begin
  {$ifdef CPUINTEL}
  if cfRAND in CpuFeatures then begin
    result := RdRand32;
    exit;
  end;
  {$endif}
  result := rs1;
  rs1 := ((result and -2)shl 12) xor (((result shl 13)xor result)shr 19);
  result := rs2;
  rs2 := ((result and -8)shl 4) xor (((result shl 2)xor result)shr 25);
  result := rs3;
  rs3 := ((result and -16)shl 17) xor (((result shl 3)xor result)shr 11);
  result := rs1 xor rs2 xor result;
end;

它将使用最新 Intel CPU 上可用的基于硬件的 PRNG，或 P. L'Ecuyer 的快速 gsl_rng_taus2 生成器（句点=2^88，即大约 10^26），这比Random() 中的模式要好得多。对于多线程，对 rs1、rs2 和 rs3 使用 threadvar 而不是 var。并且不要忘记对初始值进行异或，例如具有一些最小熵，至少 QueryPerformanceCounter()。

最后但同样重要的是，如果您想要一些独特的值，而不是完全随机的，您可以简单地使用：

var g: TGUID;
...
CreateGUID(g);

这里生成的 TGUID 被操作系统知道是唯一的。您可以轻松地使用 128 位的 TGUID 内容，它可以以比 3*32 位更好的方式用作密钥，甚至在 Internet 上也是如此。如果你需要的是唯一性，而不是随机性，很多系统只是依赖于这个 API 调用。您可以使用字符串表示形式，也可以使用 128 位 = 4*32 位二进制内容。

Answer 2

Delphi 的线性同余生成器确实不适合生成加密安全的随机数据。你绝对不能依赖它来完成这项任务。它不是为此目的而设计的，它旨在用于其他场景。

不要尝试自己实现。这很难做到正确，需要大量的知识和专业知识。人们创建不安全代码的最常见原因之一是当他们试图在没有足够知识的情况下编写自己的加密货币时。不要掉进那个陷阱。使用受信任的密码库。