为什么不能将 ContT 设为 MonadError 的实例？答案

【问题标题】：Why can't ContT be made an instance of MonadError?为什么不能将 ContT 设为 MonadError 的实例？
【发布时间】：2012-05-24 17:06:52
【问题描述】：

我有一个单子变压器堆栈，包括一个ErrorT，我想在整个东西周围包裹一个ContT r 变压器。当我尝试这样做时，我对throwError 的调用会产生类型错误——显然ContT r 不会自动成为MonadError 的实例。好吧，我想 - 我会合二为一：

instance MonadError e m => MonadError e (ContT r m) where
  throwError = lift . throwError
  catchError = liftCatch . catchError

使用liftCatch 的一些合适的定义。但是现在编译时出现错误：

src\Language\Types.hs:68:10:
    Illegal instance declaration for `MonadError e (ContT r m)'
      (the Coverage Condition fails for one of the functional dependencies;
       Use -XUndecidableInstances to permit this)
    In the instance declaration for `MonadError e (ContT r m)'

我很高兴使用 UndecidableInstances 杂注（我的印象不是太令人担忧，例如参见 this question）但我想知道将延续转换器转换为 MonadError 的实例是否有困难- 我想如果没问题的话，Control.Monad.Trans 包的作者应该已经这样做了……对吧？

【问题讨论】：

这很好，但确实采用了 UndecidableInstances，这对变形金刚库的作者来说具有潜在的危险性和不可移植性。

标签： haskell monads monad-transformers

【解决方案1】：

ContT 和 ErrorT 都允许非标准控制流。有一种方法可以在 mtl 中将 ErrorT 类型包裹在 ContT 周围：

instance (Error e, MonadCont m) => MonadCont (ErrorT e m)

但是这两个 monad 转换器不通勤。记住：

newtype Identity a = Identity {runIdentity :: a}
newtype ErrorT e m a = ErrorT {runErrorT :: m (Either e a)}
newtype ContT r m a = ContT {runContT :: (a -> m r) -> m r}

ErrorT String (ContT Bool Identity) () 在 mtl 包中可以：

ErrorT (ContT ( \ (k :: Either String () -> Identity Bool) -> k (Right ()) ) )

ContT r (ErrorT e Identity) a 在 mtl 包中不行。但你可以写。

你想要在组合单子中的 (>>=) 的语义是什么？您希望您的嵌套错误处理程序堆栈如何与非本地 callCC 交互？

我可以这样写：

{-# LANGUAGE FlexibleInstances, MultiParamTypeClasses, UndecidableInstances   #-}
import Control.Monad
import Control.Monad.Cont
import Control.Monad.Error
import Data.Function
import Data.IORef

handleError :: MonadError e m => (e -> m a) -> m a -> m a
handleError = flip catchError

test2 :: ErrorT String (ContT () IO) ()
test2 = handleError (\e -> throwError (e ++ ":top")) $ do
  x <- liftIO $ newIORef 1
  label <- callCC (return . fix)
  v <- liftIO (readIORef x)
  liftIO (print v)
  handleError (\e -> throwError (e ++ ":middle")) $ do
    when (v==4) $ do
      throwError "ouch"
  when (v < 10) $ do
         liftIO (writeIORef x (succ v))
         handleError (\e -> throwError (e ++ ":" ++ show v)) label
  liftIO $ print "done"

go2 = runContT (runErrorT test2) (either error return)

{-

*Main> go2
1
2
3
4
*** Exception: ouch:middle:top

-}

以上内容仅适用于 mtl，这是新实例及其工作方式：

instance MonadError e m => MonadError e (ContT r m) where
  throwError = lift . throwError
  catchError op h = ContT $ \k -> catchError (runContT op k) (\e -> runContT (h e) k)

test3 :: ContT () (ErrorT String IO) ()
test3 = handleError (\e -> throwError (e ++ ":top")) $ do
  x <- liftIO $ newIORef 1
  label <- callCC (return . fix)
  v <- liftIO (readIORef x)
  liftIO (print v)
  handleError (\e -> throwError (e ++ ":middle")) $ do
    when (v==4) $ do
      throwError "ouch"
  when (v < 10) $ do
         liftIO (writeIORef x (succ v))
         handleError (\e -> throwError (e ++ ":" ++ show v)) label
  liftIO $ print "done"

go3 = runErrorT (runContT test3 return)

{-

*Main> go3
1
2
3
4
Left "ouch:middle:3:middle:2:middle:1:middle:top"

-}

【讨论】：