PROLOG 中的填字游戏求解器

Question

天堂岛的克里奥尔语有14个字：“放弃”、“鲍鱼”、“字谜”、“船”、“船夫”、“孩子”、“连接”、“优雅”、“增强”、“岛屿” ”、“男人”、“沙子”、“太阳”和“女人”。

天堂时代有 发表了这个填字游戏：

填字游戏包含 14 个单词中的一些单词，但没有其他单词。

写 一个从

开始的Prolog程序

word(X) :-
member(X,
[
[a,b,a,n,d,o,n], [a,b,a,l,o,n,e], [a,n,a,g,r,a,m],
[b,o,a,t], [b,o,a,t,m,a,n], [c,h,i,l,d],
[c,o,n,n,e,c,t], [e,l,e,g,a,n,t], [e,n,h,a,n,c,e],
[i,s,l,a,n,d], [m, a, n], [s,a,n,d],
[s,u,n], [w, o, m, a, n]
]).

solution(H1,H2,H3,V1,V2,V3) :-

并以这样的方式定义谓词solution

solution(H1,H2,H3,V1,V2,V3)

当且仅当 H1、H2、H3、V1、V2 和 V3 是天堂的有效词时为真 当写入上面给出的网格时形成有效填字游戏的岛屿。 （例如H1的第二个字母应该和第二个字母重合 V1.)

使用查询

?- solution(H1,H2,H3,V1,V2,V3).

解决填字游戏。找到填字游戏的所有解决方案。

提示：您可能希望从较小的填字游戏和较不丰富的游戏开始 词典。

Answer 1

看图，字都是用字母写的，图里什么都有，用Prolog行翻译（我的方案是12行，一个字2行）。

[编辑] 每个人都有自己的解决方案，这是我的：

solution(H1,H2,H3,V1,V2,V3) :-
    H1 = [_,A2,_,A4,_,A6,_],
    H2 = [_,B2,_,B4,_,B6,_],
    H3 = [_,C2,_,C4,_,C6,_],
    V1 = [_,A2,_,B2,_,C2,_],
    V2 = [_,A4,_,B4,_,C4,_],
    V3 = [_,A6,_,B6,_,C6,_],
    maplist(word, [H1,H2,H3,V1,V2,V3]).

PS 我原来 写字（H1）， 单词(H2) ...

Answer 2

唯一的域选择 select/2 可以解决问题：

select([A|As],S):- select(A,S,S1),select(As,S1).
select([],_). 
words(X) :- X = [
    [a,b,a,n,d,o,n], [a,b,a,l,o,n,e], [a,n,a,g,r,a,m],
    [b,o,a,t],       [b,o,a,t,m,a,n], [c,h,i,l,d],
    [c,o,n,n,e,c,t], [e,l,e,g,a,n,t], [e,n,h,a,n,c,e],
    [i,s,l,a,n,d],   [m, a, n],       [s,a,n,d],
    [s,u,n],         [w, o, m, a, n]
    ].
solve(Crossword):- words(Words), 
    Crossword = [ [_,A2,_,A4,_,A6,_],
                  [_,B2,_,B4,_,B6,_],
                  [_,C2,_,C4,_,C6,_],
                  [_,A2,_,B2,_,C2,_],
                  [_,A4,_,B4,_,C4,_],
                  [_,A6,_,B6,_,C6,_] ],
    select(Crossword, Words).
solve:- solve(Crossword),
        maplist(writeln, Crossword), writeln(';'), fail 
     ;  writeln('No more solutions!').

测试：

7 ?- solve.
[a, b, a, n, d, o, n]
[e, l, e, g, a, n, t]
[e, n, h, a, n, c, e]
[a, b, a, l, o, n, e]
[a, n, a, g, r, a, m]
[c, o, n, n, e, c, t]
;
[a, b, a, l, o, n, e]
[a, n, a, g, r, a, m]
[c, o, n, n, e, c, t]
[a, b, a, n, d, o, n]
[e, l, e, g, a, n, t]
[e, n, h, a, n, c, e]
;
No more solutions!

此解决方案仅允许在拼图中使用唯一单词（不允许重复）。这可能是也可能不是您想要的。

Answer 3

本身不是 Prolog 程序，但可以在 Hakan Kjellerstrand's excellent blog on CP 中找到使用约束逻辑编程的解决方案。它在 ECLiPSe 中，但很容易适应具有有限域求解器的其他 Prolog 系统。使用 CLP 而不是纯 Prolog 将使搜索速度更快。

Answer 4

solution(H1, H2, H3, V1, V2, V3) :-
    crosswordize([H1,H2,H3], [V1,V2,V3]),
    maplist(word, [H1,H2,H3,V1,V2,V3]).

crosswordize([], [[_],[_],[_]]).
crosswordize([[_, X1, _, X2, _, X3, _]|Lines],
             [[_, X1|R1], [_, X2|R2], [_, X3|R3]]) :-
    crosswordize(Lines, [R1,R2,R3]).

算法不难得到：

• 我们通过 crosswordize/2 谓词调用构建网格
• 我们告诉 prolog 每个列表都是一个单词

crosswordize/2 谓词在构建行时一次通过两个单元格的列。如果你没有得到它，你仍然可以像 Will 那样“硬编码”它，它也可以工作！

Answer 5

这里的理论是检查垂直和水平单词中与自己对应的字母。这可以通过在word 规则中使用占位符来实现。查看这个要点https://gist.github.com/ITPol/f8f5418d4f95015b3586 它给出了一个声称没有重复的答案。但是，来自 SQL，我认为正确地抑制重复将需要一个类似于V1 @< V2 的解决方案；因为仅仅使用“不等于”是不够的。请原谅多个“[k]nots”；它实际上并没有那么复杂。双关语意（：