向量排序

Question

我有一个算法来订购一个向量l(i)，其中的组件按升序排列，我还生成了一个向量顺序D(i)，它告诉我每个组件来自哪里，所以我可以回到原来的（无序）向量。

顺序和顺序向量很好，当我想回到原来的时候出现问题。由于某种原因它不起作用，它重复向量的组件而不是按特定顺序。我不知道它是什么。

代码如下：

program order
  implicit none
  integer i,j,k,q
  integer l(7),D(7)
  real x


  do i=1,7
     call random_number (x)
     l(i)=1+FLOOR(13*x)
  enddo
  Write(*,*) "Without order"
  do i=1,7
     Write(*,*) l(i)
  enddo
  do i=1,7
     D(i)=i
  enddo
  
  do i=1,6
     do j=i+1,7
        if(l(i).gt.l(j))then
        k=l(i)
        l(i)=l(j)
        l(j)=k
        q=D(i)
        D(i)=D(j)
        D(j)=q
        endif
     enddo
  enddo

  Write(*,*) "Ordered"


  do i=1,7
     Write(*,*) l(i)
  enddo
  Write(*,*) "Order vector"
   do i=1,7
      Write(*,*) D(i)
   enddo
  do i=1,7
    l(D(i))=l(i)
  enddo
  Write(*,*) "The original vector is"
  do i=1,7
    Write(*,*) l(i)
  enddo

endprogram order

Answer 1

正如@albert 指出的那样，因为您的l(D(i))=l(i) 循环就地覆盖了l，所以您正在破坏信息。考虑一个简单的例子

nmax = 2
l = [1,2]
D = [2,1]

展开你的循环给出

l(D(1))=l(1)
l(D(2))=l(2)

即

l(2)=l(1)
l(1)=l(2)

并跟踪l 的值，我们看到

! l = [1,2]
l(2)=l(1)
! l = [1,1]
l(1)=l(2)
! l = [1,1]

因此，您要么需要在循环之前制作l 的副本，然后从那里开始工作，要么正如@steve 指出的那样，您需要使用vector subscript 在一个操作中完成整个操作，在这种情况下整个循环会变成

l(D) = l

确实，可以使用整个数组操作而不是循环来简化大部分代码，例如

program order
  implicit none
  integer :: i,j,k,q
  integer, parameter :: nmax=7
  integer :: l(nmax),D(nmax)
  real :: x(nmax)
  
  ! Set `l` to a random vector.
  call random_number(x)
  l = 1+floor(13*x)
  
  write(*,*) "Without order"
  write(*,'(I2)') l
  
  ! Set `D` to [1,2,3,4,5,6,7].
  D = [(i, i=1, nmax)]
  
  ! Sort `l` and `D` together.
  do i=1,nmax-1
    do j=i+1,nmax
      if (l(i) > l(j)) then
        ! Swap `l(i)` and `l(j)`.
        l([i,j]) = l([j,i])
        ! Swap `D(i)` and `D(j)`.
        D([i,j]) = D([j,i])
      endif
    enddo
  enddo

  write(*,*) "Ordered"
  write(*,'(I2)') l
  
  write(*,*) "Order vector"
  write(*,'(I2)') D
  
  ! Unsort `l`.
  l(D) = l
  
  write(*,*) "The original vector is"
  write(*,'(I2)') l
end program order