Visual Basic 中的矩阵

Question

所以我有一个任务是创建一个方阵，然后从中返回行和列的平均值，虽然有一些问题

Dim m, n, i, j As Integer
        Dim A(2, 2) As Integer
        Console.Write(vbLf & "Enter The Matrix Elements any two : ")
        For i = 0 To 2 - 1
            For j = 0 To 2 = 1
                A(i, j) = Convert.ToInt16(Console.ReadLine())
            Next
        Next
        Console.Clear()
        Console.WriteLine(vbLf & "Matrix A : ")
        For i = 0 To 2 - 1
            For j = 0 To 2 - 1
                Console.Write(vbLf & "{0}", A(i, j))
            Next

            Console.WriteLine(" ")
        Next


        Console.WriteLine(vbLf & "Transpose Matrix : ")

        For i = 0 To 2 - 1
            For j = 0 To 2 - 1
                Console.Write(vbLf & "{0}", A(j, i))

            Next

            Console.WriteLine(" ")
        Next
    End Sub

这是我的代码，我知道它应该是一个方阵，所以我该怎么做从用户那里获取价值，或者有人可以帮助我

Answer 1

为了使其具有通用性，请使用GetUpperBound() 函数来确定数组中每个维度的元素数量（但是应该相同，因为您有一个方阵）：

Sub Main()
    Dim size As Integer = 3
    Dim numberWidth As Integer = 2
    Dim format As String = "D" & numberWidth

    Dim A(size - 1, size - 1) As Integer
    For i As Integer = 0 To A.GetUpperBound(0)
        For j As Integer = 0 To A.GetUpperBound(1)
            Console.Write(String.Format("Enter The Matrix Element at A[Row {0}, Col {1}]: ", i, j))
            A(i, j) = Convert.ToInt16(Console.ReadLine())
        Next
    Next

    Console.WriteLine("Matrix A :")
    For i As Integer = 0 To A.GetUpperBound(0)
        Console.Write("| ")
        For j As Integer = 0 To A.GetUpperBound(1)
            Console.Write("{0} ", A(i, j).ToString(format))
        Next
        Console.WriteLine("|")
    Next

    Console.WriteLine("Transpose Matrix :")
    For i As Integer = 0 To A.GetUpperBound(0)
        Console.Write("| ")
        For j As Integer = 0 To A.GetUpperBound(1)
            Console.Write("{0} ", A(j, i).ToString(format))
        Next
        Console.WriteLine("|")
    Next
    Console.ReadLine()
End Sub

输出：

Enter The Matrix Element at A[Row 0, Col 0]: 1
Enter The Matrix Element at A[Row 0, Col 1]: 2
Enter The Matrix Element at A[Row 0, Col 2]: 3
Enter The Matrix Element at A[Row 1, Col 0]: 4
Enter The Matrix Element at A[Row 1, Col 1]: 5
Enter The Matrix Element at A[Row 1, Col 2]: 6
Enter The Matrix Element at A[Row 2, Col 0]: 7
Enter The Matrix Element at A[Row 2, Col 1]: 8
Enter The Matrix Element at A[Row 2, Col 2]: 9
Matrix A :
| 01 02 03 |
| 04 05 06 |
| 07 08 09 |
Transpose Matrix :
| 01 04 07 |
| 02 05 08 |
| 03 06 09 |

下面是一个如何计算每行的 SUM 的简单示例：

Dim Total as Integer
For row As Integer = 0 To A.GetUpperBound(0)
    Total = 0 ' reset for each row/column
    For col As Integer = 0 To A.GetUpperBound(1)
        Total = Total + A(row, col)            
    Next
    Console.WriteLine("Row " & row & " total: " & Total)
    ' ... do something else with "Total" here; like compute an average ...
Next

计算列总数的代码非常相似，只是交换了For row 和For col 行的位置。