Userform 根据条件使 Excel 崩溃

Question

我遇到了一个我不明白的有趣问题。

在 VBA 中，我想在用户双击单元格时加载用户窗体，具体取决于单元格内容。但是根据我问的情况，一旦我退出 Sub，Excel 就会崩溃（即使在 UserForm 关闭后它也会继续执行代码）。

这行得通：

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
    Dim myForm As New UserForm1
    If Target.Cells(1).Value = "" Then
        myForm.Show
    End If
    Debug.Print ("OK")
End Sub

而这三个使 Excel 崩溃：

1.

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
    Dim myForm As New UserForm1
    If Target.Cells(1).Value <> "" Then
        myForm.Show
    End If
    Debug.Print ("OK")
End Sub

2.

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
    Dim myForm As New UserForm1
    If Not Target.Cells(1).Value = "" Then
        myForm.Show
    End If
    Debug.Print ("OK")
End Sub

3.

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
    Dim myForm As New UserForm1
    If Target.Cells(1).Value = "Test" Then
        myForm.Show
    End If
    Debug.Print ("OK")
End Sub

我正在使用一个空的用户窗体进行测试

Answer 1

尝试更改 If 块中的代码，使其执行 Cancel = True 以忽略双击操作并预先加载表单，如下所示：

If Target.Cells(1).Value = "Test" Then
    Cancel = True
    Load myForm
    myForm.Show
End If

Answer 2

Cancelling the cell edit mode entry 似乎是一个很好的方法来限制可能出错的事情的数量。

还有更多。

Dim myForm As New UserForm1

这是在本地范围内创建一个 自动实例化 UserForm1 对象。由于Dim 语句不可执行，这意味着无论您是否Show 表单，只要进入过程范围，就会创建对象。

使用With 块，您可以轻松避免无条件创建该对象，甚至无需为其声明变量：

Private Sub Workbook_SheetBeforeDoubleClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
    If Target.Cells(1).Value = "Test" Then
        Cancel = True
        With New UserForm1
            .Show
        End With
    End If
    Debug.Print "OK"
End Sub

这样，表单实例只有在需要时才会被创建。避免默认实例陷阱的巨大荣誉 - 你可以阅读更多关于on my blog的信息。

请注意，我还删除了 Debug.Print 参数列表周围的多余括号。括号在过程调用中实际上是有害的；当您将它们与多参数过程一起使用时，您会遇到编译错误，当您需要传递对象引用时会遇到运行时错误，以及当您打算传递参数时会遇到逻辑错误ByRef - 像这样使用的括号，正在强制 VBA 将表达式 作为值 进行计算，并始终传递结果 ByVal，而不管被调用的过程是否表示它正在使用 ByRef 参数。

在调用 函数 并在局部变量中捕获其返回值时使用括号。