COUNTIF 使 Excel 崩溃答案

【问题标题】：COUNTIF crashes ExcelCOUNTIF 使 Excel 崩溃
【发布时间】：2013-08-27 03:28:03
【问题描述】：

我有一个包含日期和电子邮件地址列的 Excel 工作表，按日期排序。我想计算电子邮件地址在当前出现之前出现在工作表中的次数。 COUNTIF(B$1:B1,B2) 公式有效，但是当我将其复制到超过 50,000 条记录时，Excel 崩溃了。我总共有 200,000 条记录。

还有其他 Excel (2010) 可以处理的解决方案吗？

【问题讨论】：

我认为人们将 VBA 用于大型数据集，如下所述：stackoverflow.com/questions/6134002/…
您是否尝试过禁用自动计算，然后手动计算（我认为是 F9）？
它真的崩溃了，还是进入（没有响应）？
在 mac 和 PC 上都崩溃了

标签： excel excel-2010

【解决方案1】：

这是一个在合理时间内运行的 VBA 子程序

Sub countPrior()
    Dim dic As Object
    Dim i As Long
    Dim dat As Variant
    Dim dat2 As Variant

    ' Get source data range, copy to variant array
    dat = Cells(1, 2).Resize(Cells(Rows.Count, 1).End(xlUp).Row, 1)
    ' create array to hold results
    ReDim dat2(1 To UBound(dat, 1), 1 To 1)
    ' use Dictionary to hold count values
    Set dic = CreateObject("scripting.dictionary")
    ' loop variant array
    For i = 1 To UBound(dat, 1)
        If dic.Exists(dat(i, 1)) Then
            ' return count
            dat2(i, 1) = dic.Item(dat(i, 1))
            ' if value already in array, increment count
            dic.Item(dat(i, 1)) = dic.Item(dat(i, 1)) + 1
        Else
            ' return count
            dat2(i, 1) = 0
            ' if value not already in array, initialise count
            dic.Add dat(i, 1), 1
        End If
    Next
    ' write result to sheet
    Cells(1, 3).Resize(Cells(Rows.Count, 1).End(xlUp).Row, 1) = dat2
End Sub

【讨论】：

【解决方案2】：

如果您可以选择宏，这里有一个宏可以为您完成此任务。我假设您的地址在 B 列中，并且您希望在 C 列中记录之前出现的次数，您可以根据工作表的结构方式对其进行修改。

Sub countPrior()
Application.ScreenUpdating=False
bottomRow = Range("B1000000").End(xlUp).Row
   For i = 2 To bottomRow
   cellVal = Range("B" & i).Value
   counter = 0
      For j = 1 To i - 1
         If Range("B" & j).Value = cellVal Then
         counter = counter + 1
         End If
      Next j
   Range("C" & i).Value = counter
   Next i
Application.ScreenUpdating=True
End Sub

【讨论】：

你试过在 200,000 行上运行它吗？等待它运行，你会变老！
也许你会，与此同时我会做其他事情。