根据字段值将一个 SAS 表导出到多个 Excel 工作表中

Question

我正在尝试根据字段 (parent_account) 的值将一个 SAS 表导出到多个 Excel 工作表中。我希望每个工作表的名称与 parent_account 相同。我正在使用在http://www.tek-tips.com/viewthread.cfm?qid=1335588 找到的以下代码，但我收到了这些错误消息：

在需要数字操作数的 %EVAL 函数或 %IF 条件中找到字符操作数。 宏函数 %SCAN 的参数 2 不是数字。

%macro export_to_excel();
%local varlist idx var;

proc sql noprint;
  select distinct parent_account into: varlist separated by '||'
  from todays_activity;
quit;

%let idx = 1;
%do %while ( %scan(&varlist, &idx, %str(||)) ne %str() ); 
    %let var=%scan(&varlist, &idx, %str(||));
    proc export data=sashelp.class (where=(parent_account="&var"))
       outfile='My file location\Report.xls'
   dbms=excel; 
   sheet="&var";
quit;
%let idx = %eval(&idx + 1);
%end;
%mend export_to_excel;

%export_to_excel;

Answer 1

您可以尝试使用ODS EXCEL。这是一个使用 SASHELP.CLASS 数据集的示例。 首先确保数据按分组变量排序。

proc sort data=sashelp.class out=class ;
  by sex ;
run;

设置 ODS 以指向您的目标文件。告诉它为每个 BY 组制作一张新工作表。

ods excel file="&path/class.xlsx"  ;
ods excel options
(sheet_interval="bygroup"
 suppress_bylines="yes"
 sheet_name='GENDER'
);

您可能还想关闭其他输出目标。 然后使用 PAGEBY 选项打印文件。并关闭 ODS EXCEL 目的地

proc print data=class noobs;
  by sex ;
  pageby sex ;
  var _all_;
run;
ods excel close;

要对其进行测试，您可以尝试将其作为数据读回。但请注意，它会创建带有嵌入空格的成员名称。

options validmemname=extend;
libname xx xlsx "&path/class.xlsx";
proc copy inlib=xx outlib=work; run;
libname xx clear ;

来自 SAS 日志

NOTE: The data set WORK.GENDER has 9 observations and 5 variables.
NOTE: The data set WORK.'GENDER 2'n has 10 observations and 5 variables.

Answer 2

这可能会有所帮助

%macro export_to_excel;
    proc sql noprint;
    select distinct parent_account into: varlist separated by '@' from todays_activity;
    select count(distinct parent_account) into:n from todays_activity;
    quit;
    %do i=1 %to &n;
    %let var= %scan(&varlist,&i,"@");
    proc export data=sashelp.class (where=(parent_account="&var"))
           outfile='Your file location\Report.xls'
       dbms=excel; 
       sheet="&var";
    run;
    %end;
    %mend export_to_excel;