【问题标题】:Export Access data into Excel workbook and split data into multiple sheets based on column value将 Access 数据导出到 Excel 工作簿并根据列值将数据拆分为多个工作表
【发布时间】:2015-12-05 17:31:29
【问题描述】:

样本数据(名为“Pets_data_table”的本地访问表)

ID | Pet_Type | Pet_Owner

1      Dog        Jane Doe         
2      Cat        John Doe
3      Hamster    Bob Doe
4      Dog        Melissa Doe 
5      Cat        Aaron Doe

目前,我可以将此表中的数据导出到一个 Excel 工作簿,并根据特定字段的不同值将数据拆分到该 Excel 工作簿中的多个工作表中。我使用以下 VBA 根据“Pet_Type”字段的不同值拆分数据:

    Dim db As DAO.Database
    Set db = CurrentDb()
    Dim strPath As String
    strPath = "C:\Desktop\" & "Pets_dataset_export_" & format(date(),"yyyy-mm-dd") & ".xlsx" 
    DoCmd.TransferSpreadsheet acExport, 10, "Qry - Dog", strPath, True, "Dog"
    DoCmd.TransferSpreadsheet acExport, 10, "Qry - Cat", strPath, True, "Cat"
    DoCmd.TransferSpreadsheet acExport, 10, "Qry - Hamster", strPath, True, "Hamster"

    Set db = Nothing
    MsgBox "Export operation completed"

当我用来分割数据的字段具有少量不同的值时,这会表现良好。

但是,当我要拆分数据的字段中有大量不同的值时,效率会很低。

我想实现一种更动态的方法,允许我使用具有 1...n 个不同值的字段拆分数据集。

【问题讨论】:

  • 一种方法是加载所有内容,然后对 Pet_Type 字段进行排序,然后循环直到它发生变化并每次创建一个新工作表,新的 Pet_type 值成为工作表的名称。
  • 使用转移电子表格和合适的查询会容易得多。
  • @Fionnuala:更新了 VBA 以反映使用我当前方法的更简单方式。
  • 使用 Fionnuala 的方法,您仍然需要为每种不同的动物类型创建一个新查询。为此,请使用 sql 获取不同的动物列表,然后通过它们动态创建每个查询。查看 here 以获取有关如何执行此操作的说明。

标签: excel ms-access vba export-to-excel


【解决方案1】:

根据为您提供独特宠物类型的查询加载单个记录集 ...

SELECT DISTINCT p.Pet_Type
FROM Pets_data_table AS p;

然后遍历该记录集,将保存的查询 (qryExportMe) 更改为 SELECT 当前的 Pet_Type,然后导出查询...

Dim db As DAO.Database
Dim qdf As DAO.QueryDef
Dim rs As DAO.Recordset
Dim strPath As String
Dim strSelectOneType As String
Dim strSelectPetTypes As String

' (change strPath back to what you need)
strPath = CurrentProject.Path & Chr(92) & "Pets_dataset_export_" & _
    Format(Date, "yyyy-mm-dd") & ".xlsx"
strSelectPetTypes = "SELECT DISTINCT p.Pet_Type" & vbCrLf & _
    "FROM Pets_data_table AS p;"

Set db = CurrentDb
Set rs = db.OpenRecordset(strSelectPetTypes, dbOpenSnapshot)
Do While Not rs.EOF
    strSelectOneType = "SELECT p.ID, p.Pet_Type, p.Pet_Owner" & vbCrLf & _
        "FROM Pets_data_table AS p" & vbCrLf & _
        "WHERE p.Pet_Type='" & rs!Pet_Type.Value & "';"
    Debug.Print strSelectOneType
    Set qdf = db.QueryDefs("qryExportMe")
    qdf.SQL = strSelectOneType
    qdf.Close
    DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel12Xml, _
        "qryExportMe", strPath, True, rs!Pet_Type.Value
    rs.MoveNext
Loop
rs.Close

请注意,代码要求保存的查询 qryExportMe 存在。但它的 SQL 属性并不重要,因为您每次都将通过 Do While 主循环更改它。

【讨论】:

    猜你喜欢
    • 1970-01-01
    • 1970-01-01
    • 2017-11-28
    • 1970-01-01
    • 1970-01-01
    • 2018-08-30
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    相关资源
    最近更新 更多