如何将日期显示为从 .csv 导入的 DD MMM YYYY

Question

我有一项服务可以获取 .csv 并将其处理为 .sas7bdat。

我通过填写变量名称、长度和指定输出位置来修改现有的 .sas 模板。

我有一个场景，其中我的 .csv 的日期格式为“DD MMM YYYY”。我需要将此格式保留到输出文件中。预定义格式允许使用“DDMMMYYY”和“DD-MMM-YYYY”。我已经在模板中尝试过这些格式类型。

下面是标准字符类型的模板：

LIBNAME TempSrc "C:\Temp";
proc import datafile="\\***\FileLocation\file.csv"
        out=mydata dbms=dlm replace;
        DELIMITER= ",";
        getnames=yes;
        options ExtendObsCounter=yes;
RUN;
DATA TempSrc.fileName;
    attrib      DATEVAR length=$11  format=$11.     informat=$11.       label='Date'
            ;
            set work.mydata;
RUN;

如何修改此代码以输出如下日期“2000 年 1 月 1 日”

编辑：

如何将此值作为字符值输出到 .sas7bdat？

Answer 1

没有显示为 DD MMM YYYY 的默认格式，因此您需要自行选择。我相信以下内容为您提供了您想要实现的目标：

proc format;
picture ddmmmyy
  other= '%0d %b %Y' (datatype=date);
run;

data have;
  datevar='01 JAN 2000';
run;

data want;
  set have;
  actualdatevar=input(datevar,anydtdte11.);
  format actualdatevar ddmmmyy11.;
run;

给予：

请注意，您不能将字符变量转换为数字，因此您可能希望创建一个新变量，然后删除旧变量（也可以重命名新变量，以便最终得到相同的命名变量）。

EDIT1：适用于特定答案（现在情况更清楚了）

以下应该实现所需要的：

LIBNAME TempSrc "C:\Temp";

proc format;
picture ddmmmyy
  other= '%0d %b %Y' (datatype=date);
run;

proc import datafile="\\***\FileLocation\file.csv"
        out=mydata dbms=dlm replace;
        DELIMITER= ",";
        getnames=yes;
        options ExtendObsCounter=yes;
RUN;
/* if all you need to do is apply the format, you may be better using proc datasets */
DATA TempSrc.fileName;  
  set work.mydata;  
  format DATEVAR ddmmmyy11. ;
RUN;

EDIT2：转换为字符，以便在通用查看器中正确显示（没有自定义格式）

LIBNAME TempSrc "C:\Temp";

proc format;
picture ddmmmyy
  other= '%0d %b %Y' (datatype=date);
run;

proc import datafile="\\***\FileLocation\file.csv"
        out=mydata dbms=dlm replace;
        DELIMITER= ",";
        getnames=yes;
        options ExtendObsCounter=yes;
RUN;
/* convert numeric to character via rename */
DATA TempSrc.fileName;  
  set work.mydata (rename=(DATEVAR=DATEVAR2));  
  DATEVAR=put(DATEVAR2,ddmmmyy11.);
  drop DATEVAR2;
RUN;